software
Apple II Compilation #007 (19xx)(-)

Language: English

Apple II Compilation #007 (19xx)(-)

Notes

Disk info for Apple_II_Compilation_007_19xx__.do:

File Name: a2_Apple_II_Compilation_007_19xx_/Apple_II_Compilation_007_19xx__.do
Disk Name: DISK VOLUME #254
Physical Size (bytes): 143360
Free Space (bytes): 57856
Used Space (bytes): 85504
Physical Size (KB): 140
Free Space (KB): 56
Used Space (KB): 83
Archive Order: DOS
Disk Format: DOS 3.3
Total Sectors: 560
Free Sectors: 226
Used Sectors: 334
Tracks On Disk: 35
Sectors On Disk: 16

Disk directory for Apple_II_Compilation_007_19xx__.do:

a2_Apple_II_Compilation_007_19xx_/Apple_II_Compilation_007_19xx__.do DISK VOLUME #254
* A 004 HELLO
A 024 ADV.CAVES
A 033 SORCERY
A 041 DUKEDOM
A 032 IMHOTEP
A 021 INSPECTOR.CLOU
A 060 ADVENTURE.WITH
A 055 LOST.DUTCHMAN.
DOS 3.3 format; 57,856 bytes free; 85,504 bytes used.

Text found in Apple_II_Compilation_007_19xx__.do/ADV.CAVES.bas:

0 PRINT : GOSUB 1200
1 TI = 0:T4 = 500
4 PRINT : FOR I = 0 TO 39: PRINT "*";: NEXT
5 PRINT
7 GOSUB 2110
19 DIM V$(28),P(1),T(10,4,1),A(10,3),Q(3),S(10)
30 FOR I = 0 TO 10: FOR J = 0 TO 4: FOR K = 0 TO 1: READ T(I,J,K): NEXT K,J,I
36 A(3,0) = 1:A(0,0) = 2:A(6,0) = 3:A(1,0) = 4:A(8,0) = 5:A(1,1) = 6:A(7,0) = 7
37 P(0) = .3:P(1) = .5
40 FOR I = 1 TO 28: READ V$(I): NEXT
100 PRINT : GOSUB 1200
105 GOSUB 1500
107 PRINT
110 N$ = "": INPUT "COMMAND=";D$:H = LEN(D$):TI = TI +1000:KK = KK +1
111 IF LEFT$(D$,1) = " " THEN PRINT "11": GOTO 110
112 FOR I = 1 TO H: IF MID$ (D$,I,1) < >" " THEN NEXT
115 U = 99:B = I: IF I >5 THEN B = 5
116 C$ = LEFT$(D$,B -1): IF I > = H THEN 120
117 B = H -I: IF B >4 THEN B = 4
118 E$ = RIGHT$(D$,H -I):N$ = LEFT$(E$,B)
120 GOSUB 1100
125 IF I = 0 THEN PRINT : PRINT "I DON'T UNDERSTAND ";D$: GOTO 110
126 IF I < >14 THEN 130
127 GOSUB 2000
128 GOTO 398
130 IF I < >13 THEN 133
131 PRINT "OK!": GOSUB 2112
132 GOTO 100
133 IF I < >15 THEN 139
135 PRINT : PRINT "I HOPE YOU HAVE ENJOYED YOUR STAY": GOSUB 2000
137 END
139 O = 6: GOSUB 2183
140 IF B < >4 THEN U = L
143 V = I: IF V >15 THEN 172
144 IF U = 99 THEN F = L
146 GOSUB 1000
148 R = RND(1): IF M <100 THEN L = M: GOTO 390
150 M1 = INT(M/100):M2 = M -M1 *100:M3 = INT(M1/10):M4 = M1 -M3 *10: IF M4 = 0 THEN 160
157 IF R

16 THEN 190
179 IF O = 6 THEN PRINT : PRINT "YOU'RE KIDDING!": GOTO 398
180 IF U < >99 AND O >2 THEN 390
183 GOSUB 2183
184 IF B = 4 AND O = 8 THEN O = 7: GOSUB 2183
185 IF B = 4 THEN PRINT "IF THERE'S A ";E$;" HERE, YOU CAN'T GET IT": GOTO 398
186 O1 = O:O = 0: GOSUB 2193
188 IF C = 4 THEN PRINT : PRINT "YOUR HANDS ARE FULL": GOTO 398
189 O = O1:A(L,B) = 0:Q(C) = O: PRINT : PRINT "OK": GOTO 398
190 IF V < >17 THEN 230
191 GOSUB 2193
193 IF C = 4 AND O = 8 THEN O = 7: GOSUB 2193
196 IF C = 4 THEN 238
197 O1 = O:O = 0: GOSUB 2183
199 IF B = 4 THEN PRINT : PRINT "NO MORE ROOM HERE": GOTO 398
200 I = B:O = O1:A(L,I) = O:Q(C) = 0: IF O < >1 THEN 300
201 O = 6: GOSUB 2183
203 IF B = 4 THEN 390
204 A(L,B) = 0: PRINT : PRINT "AMAZINGLY THE DRAGON IS TERRIFIED OF KITTENS"
205 PRINT " HE HAS FLOWN OFF ELSEWHERE IN THE CAVE "
210 R = INT( RND(1) *10)
215 FOR B = 0 TO 3: IF A(R,B) = 0 THEN 218
216 NEXT
217 GOTO 210
218 IF R = L THEN 210
220 A(R,B) = 6:F = U:U = 99
221 M = RND(1): IF M >0.25 THEN 398
222 PRINT : PRINT "HOWEVER, THE KITTEN HAS RUN OFF SCARED ":A(L,I) = 0
223 M = INT( RND(1) *10): IF M = L OR M = R THEN 223
224 FOR I = 1 TO 3: IF A(M,I) = 0 THEN A(M,I) = 1: GOTO 398
225 NEXT
226 GOTO 223
230 IF V < >18 THEN 250
231 GOSUB 2193
238 IF C = 4 THEN PRINT : PRINT "YOU HAVE NO ";E$: GOTO 398
240 IF O = 2 AND T4 = 500 THEN PRINT : PRINT "THE LAMP IS NOW LIT "
241 T4 = TI/3600 +15:T3 = 0: GOTO 398
245 GOTO 270
250 IF V < >19 THEN 280
255 GOSUB 2183
257 IF B = 4 THEN PRINT "ITS NOT HERE!": GOTO 398
260 IF O = 6 THEN 179
265 IF O = 1 THEN S2 = 0: PRINT "YOU'RE SICK AND I WON'T PLAY ANYMORE!": END
270 PRINT "YOU CAN'T DO THAT!": GOTO 398
280 IF V < >20 THEN 398
285 GOSUB 2193
287 IF C = 4 THEN 270
290 E$ = "OIL":O = 7: GOSUB 2193
291 IF C = 4 THEN 270
292 Q(C) = 8: PRINT : PRINT "THE LAMP IS REFILLED!"
294 IF T4 = 600 THEN T4 = 500: GOTO 398
296 T3 = 0:T4 = TI/3600 +15: GOTO 398
300 IF O < >7 THEN 398
310 A(L,B) = 8: PRINT : PRINT "WHOOPS! SPILLED THE OIL ": GOTO 398
390 IF U = 99 THEN 398
395 IF L < >F THEN PRINT : PRINT "CAN'T YOU SEE THE DRAGON?":L = U
398 IF L = 0 OR F = 0 OR L = 2 THEN 490
400 O = 2: GOSUB 2193
401 IF C < >4 AND T4 <500 THEN 490
402 GOSUB 2183
403 IF B < >4 AND T4 <500 THEN 490
410 L = F: PRINT : PRINT "YOU CAN'T WANDER THE CAVE IN THE DARK!": GOTO 490
490 IF S(L) = 0 THEN S(L) = 1
492 IF T4 >TI/3600 THEN 100
494 IF T3 = 0 THEN PRINT : PRINT "YOUR LAMP IS BURNING LOW":T3 = T4 +5: GOTO 100
496 IF TI/3600 >T3 THEN T4 = 600: PRINT : PRINT "YOUR LAMP HAS GONE OUT!"
499 GOTO 100
1000 M = 1000: FOR I = 0 TO 4
1010 IF T(L,I,0) = V THEN M = T(L,I,1)
1015 IF T(L,I,0) < >0 THEN NEXT
1020 RETURN
1100 I2 = 4:I1 = 28: IF LEN(C$) = 1 THEN I1 = 11:I2 = 1
1105 FOR I = I1 TO 1 STEP -1
1107 IF C$ = LEFT$(V$(I),I2) THEN RETURN
1110 NEXT : RETURN
1200 ON L +1 GOSUB 1205,1212,1222,1232,1242,1252,1262,1272,1282,1292,1302
1202 RETURN
1205 PRINT "YOU ARE AT A NARROW CRACK IN SOME ROCKS"
1206 PRINT "A SIGN SAYS 'THIS WAY IN'": RETURN
1212 PRINT "YOU ARE AT A ROUND PIT. A LEDGE LEADS OFF TO THE S": RETURN
1222 PRINT "LOST IN THE WOODS, ALL DIRECTIONS LOOK ALIKE": RETURN
1232 PRINT "YOU ARE AT A PILE OF RUBBLE AT THE N END OF A LOW"
1233 PRINT "PASSAGE"
1234 PRINT "A SIGN SAYS 'MAGIC MAY WORK HERE'": RETURN
1242 PRINT "YOU ARE IN A LOW E/W CRAWL WAY. FAINT LIGHT CAN"
1243 PRINT "BE SEEN OVERHEAD.": RETURN
1252 PRINT "YOU'RE IN A GREAT HALL. TO THE N A NARROW CRACK CAN"
1253 PRINT "BE SEEN. THERE IS A PASSAGE TO THE E. TO THE S A"
1254 PRINT "CHASM CROSSES THE HALL FROM E TO W.": RETURN
1262 PRINT "YOU'RE IN A ROUND CHAMBER. PASSAGES LEAD SEVERAL WAYS"
1263 PRINT "IN THE CENTER IS A ROCK PILE REACHING THE CEILING": RETURN
1272 PRINT "YOU STAND AT THE N EDGE OF A 3 METER DEEP CHASM"
1273 PRINT "ABOUT 2 METERS WIDE. THE HALL GOES ON BEYOND.": RETURN
1282 PRINT "YOU'RE TEETERING ON THE BRINK OF A 3 METER DEEP"
1283 PRINT "CHASM. A GREAT HALL IS SEEN BEYOND TO THE NORTH."
1284 PRINT "PASSAGES RUN E & W": RETURN
1292 PRINT "YOU'RE AT THE START OF A STEEP,SMOOTH SLIPPERY"
1293 PRINT "RAMP GOING DOWN TO THE S & E. IT LOOKS TOO STEEP"
1294 PRINT "TO CLIMB BACK UP.": RETURN
1302 PRINT "LYING BRUISED AND BLEEDING AT THE FOOT OF A 3"
1303 PRINT "METER HIGH SHEAR WALL, YOU STARE UP AT A DISTANT"
1304 PRINT "ARCHED ROOF AND PONDER YOUR FATE.": RETURN
1400 ON M2 +1 GOSUB 1402,1412,1422
1401 RETURN
1402 PRINT "YOU CAN'T DO THAT HERE!": RETURN
1412 PRINT "THAT DIDN'T WORK THIS TIME!": RETURN
1422 PRINT "THE WALLS ARE TOO SLIPPERY FOR EASY CLIMBING!": RETURN
1500 FOR I = 0 TO 3: IF A(L,I) = 0 THEN 1590
1530 ON A(L,I) GOTO 1540,1545,1550,1555,1560,1565,1570,1575
1535 GOTO 1590
1540 PRINT : PRINT "A CUTE KITTEN SCAMPERS ABOUT UNDER FOOT.": GOTO 1590
1541 GOTO 1590
1545 PRINT : PRINT "AN OIL LAMP IS ON THE GROUND.": GOTO 1590
1550 PRINT : PRINT "A LARGE GOLD NUGGET IS HERE.": GOTO 1590
1555 PRINT : PRINT "A PILE OF SILVER COINS IS STREWN ABOUT.": GOTO 1590
1560 PRINT : PRINT "A RUBY GLEAMS NEARBY.": GOTO 1590
1565 PRINT : PRINT "A LARGE DRAGON BLOCKS YOUR PATH.": GOTO 1590
1570 PRINT : PRINT "A JAR OF OIL STANDS NEARBY.": GOTO 1590
1575 PRINT : PRINT "AN EMPTY JAR LIES ON THE GROUND.": GOTO 1590
1590 NEXT I
1591 FOR I = 1 TO 40: PRINT "-";
1592 NEXT I
1595 RETURN
2000 Z = 0: FOR I = 0 TO 10:Z = Z +S(I) *4: NEXT
2010 FOR I = 0 TO 3: IF A(0,I) = 1 OR (A(0,I) >2 AND A(0,I) <6) THEN Z = Z +14
2012 NEXT : PRINT : PRINT "IN ";KK;" MOVES IN THE CAVE, YOUR SCORE IS ";Z
2015 RETURN
2110 PRINT "EXPLORE A DEEP AND MYSTERIOUS CAVE, BUT WATCH OUT"
2111 PRINT "FOR THE UNEXPECTED!": PRINT
2112 PRINT : PRINT "ENTER COMMANDS SUCH AS -": PRINT " NORTH,UP,IN,GET,DROP,LIGHT,HELP,SCORE,QUIT"
2113 PRINT : FOR I = 1 TO 40: PRINT "*";: NEXT : RETURN
2114 FOR I = 1 TO 50: PRINT "*";
2115 NEXT : RETURN
2183 FOR B = 0 TO 3: IF A(L,B) = O THEN RETURN
2184 NEXT : RETURN
2193 FOR C = 0 TO 3: IF Q(C) = O THEN RETURN
2194 NEXT : RETURN
9010 DATA 10,4,1,2,2,2,3,2,4,2
9011 DATA 2,8,5,6,7,6,9,51203,8,5
9012 DATA 1,02100,2,02100,3,02100,4,02100,0,0
9013 DATA 2,4,6,52109,8,52109,9,51201,0,0
9014 DATA 3,3,4,5,6,0,8,0,11,0
9015 DATA 1,6,2,7,3,4,8,4,9,51108
9016 DATA 1,06205,4,06205,6,1,7,6,8,1
9017 DATA 1,5,5,10,8,10,7,10208,5,10
9018 DATA 3,9,4,1,5,10,8,10,7,10107
9019 DATA 1,8,2,3,5,3,7,3,3,3
9020 DATA 8,52107,9,51104,6,10,7,10,0,0
9100 DATA NORT,SOUT,EAST,WEST,DOWN,UP,JUMP,CLIM,MAGI,IN,OUT,JPO
9101 DATA HELP,SCOR,QUIT,GET,DROP,LIGH,KILL,FILL
9200 DATA KITT,LAMP,GOLD,COIN,RUBY,DRAG,OIL,JAR
9999 END

Text found in Apple_II_Compilation_007_19xx__.do/ADVENTURE.WITH.bas:

0 REM BY GREG HASSETT
10 TEXT : CLEAR
20 IF NA$ < >"" THEN 50
30 HOME : INPUT "WHAT IS YOUR NAME ?";NA$
40 NA$ = NA$ +"/JOURNEY"
50 HOME : VTAB 11
60 PRINT TAB( 12)"ADVENTURE WITHIN"
70 PRINT TAB( 15)"THE EARTH"
80 FOR EW = 1 TO 300: NEXT
90 CP = 1: GOSUB 2010
100 HOME
110 GOSUB 1910: GOSUB 1800
120 IF CP = 18 AND (VB < >25 OR NO < >21) THEN PRINT "HORRORS! THE TROLL THROWS AN AXE AT ME! I AM DEAD.": GOTO 1510
130 IF CP = 18 THEN PRINT M2$:F5 = 1: GOSUB 1800
140 IF NO <23 OR VB >1 OR NO >30 THEN 230
150 IF NO < = 26 THEN FD = FD +1: GOTO 160
155 FD = -10000
160 IF NO >26 THEN NO = NO -4
170 NO = NO -22
180 IF CP = 10 AND NO = 1 THEN PRINT "AND FALL INTO THE LAVA??? FAT CHANCE!": GOSUB 1800: GOTO 140
190 IF CP = 11 AND NO = 2 THEN PRINT "DO YOU KNOW WHAT LAVA IS??? IT'S HOT, THAT'S WHAT!": GOSUB 1800: GOTO 140
200 IF CP = 29 AND OB(10,0) = 29 AND (NO = 4 OR NO = 2) THEN PRINT "THE HYDRA WON'T LET ME THROUGH!": GOSUB 1800: GOTO 140
210 IF P(CP,NO) = 0 THEN PRINT "I CAN'T GO THAT WAY!": GOSUB 1800: GOTO 140
220 CP = P(CP,NO): GOTO 100
230 IF VB < >2 AND VB < >20 THEN 310
240 IF NO = 10 AND OB(33,0) = CP THEN PRINT "IT IS SORT OF HEAVY, YOU KNOW.": GOSUB 1800: GOTO 140
250 IF NO = 0 THEN PRINT "I DON'T KNOW WHAT A '"NO$"' IS.": GOSUB 1800: GOTO 140
260 IF OB(NO,0) < >CP THEN PRINT "I DON'T SEE IT HERE.": GOSUB 1800: GOTO 140
270 IF NO = 10 OR NO = 20 THEN PRINT "OH GIVE ME A BREAK!!": GOSUB 1800: GOTO 140
280 IF OB(NO,0) = -1 THEN PRINT "I'M ALREADY CARRYING IT.": GOSUB 1800: GOTO 140
290 IF OB(NO,0) = CP AND NT > = 6 THEN PRINT "I CAN'T CARRY ANY MORE. YOU'LL HAVE TO DROP SOMETHING.": GOSUB 1800: GOTO 140
300 IF OB(NO,0) = CP THEN PRINT "CHECK.":NT = NT +1:OB(NO,0) = -1: GOSUB 1800: GOTO 140
310 IF VB < >4 AND VB < >29 THEN 360
320 F3 = 0
330 PRINT "I AM CURRENTLY CARRYING :": FOR I = 1 TO LO: IF OB(I,0) = -1 THEN PRINT OB$(I):F3 = 1
340 NEXT I: IF F3 = 0 THEN PRINT "NOTHING."
350 GOSUB 1800: GOTO 140
360 IF VB = 3 THEN 100
370 IF NO = 0 AND VB = 0 THEN PRINT "THAT DOESN'T MAKE ANY SENSE TO ME.": GOSUB 1800: GOTO 140
380 IF VB < >5 THEN 440
390 J = 0
400 FOR I = 1 TO LO: IF OB(I,0) = 1 THEN J = J +OB(I,1)
410 NEXT I: PRINT "OUT OF A MAXIMUM OF 175 POINTS, YOU HAVE "J"."
420 IF J = 0 THEN PRINT "BOY, YOU STINK!"
430 GOSUB 1800: GOTO 140
440 IF VB < >6 AND VB < >22 THEN 510
450 IF NO$ < >"EVERYTHING" AND NO$ < >"ALL" THEN 490
460 FOR I = 1 TO LO: IF OB(I,0) = -1 THEN OB(I,0) = CP
470 NEXT I:NT = 0
480 PRINT "OKAY.": GOSUB 1800: GOTO 140
490 IF OB(NO,0) < > -1 THEN PRINT "HOW CAN I DROP WHAT I'M NOT HOLDING???": GOSUB 1800: GOTO 140
500 OB(NO,0) = CP: PRINT "O.K.":NT = NT -1: GOSUB 1800: GOTO 140
510 IF VB < >7 AND VB < >28 THEN 550
520 IF H$(CP) = "" THEN PRINT "YOU GOT ME INTO THIS MESS, NOW GET ME OUT!"
530 PRINT H$(CP):H$(CP) = ""
540 GOSUB 1800: GOTO 140
550 IF VB < >8 THEN 640
560 HOME : INPUT "SAVE TO CASSETTE OR DISK ?";IO$:IO$ = LEFT$(IO$,1): IF IO$ < >"C" AND IO$ < >"D" THEN 560
561 IF IO$ = "C" THEN 570
562 PRINT "PRESS WHEN DISK": INPUT "PREPARATIONS ARE MADE.";XX$: PRINT "SAVING."
563 PRINT "OPEN"NA$
564 FOR I = 1 TO LO: PRINT "WRITE"NA$: IF OB$(I) = "" THEN 566
565 PRINT OB(I,0): PRINT OB(I,1)
566 NEXT I: PRINT CP
567 PRINT "CLOSE"NA$
568 GOTO 630
570 PRINT "PRESS WHEN CASSETTE": INPUT "PREPARATIONS ARE MADE.";XX$: PRINT "SAVING."
571 FOR I = 1 TO LO: IF OB$(I) = "" THEN 574
572 XX(I,0) = OB(I,0)
573 XX(I,1) = OB(I,1)
574 NEXT I
575 XX(LO +1,0) = CP
576 STORE XX
630 GOSUB 1800: GOTO 140
640 IF VB < >9 THEN 720
650 HOME : INPUT "LOAD FROM CASSETTE OR DISK ?";IO$:IO$ = LEFT$(IO$,1): IF IO$ < >"C" AND IO$ < >"D" THEN 650
660 IF IO$ = "C" THEN 670
661 PRINT "PRESS WHEN DISK": INPUT "PREPARATIONS ARE MADE.";XX$: PRINT "LOADING.": PRINT "OPEN"NA$
662 FOR I = 1 TO LO: PRINT "READ"NA$: IF OB$(I) = "" THEN 664
663 INPUT OB(I,0),OB(I,1)
664 NEXT I: INPUT CP
665 PRINT "CLOSE"NA$: GOTO 710
670 PRINT "PRESS WHEN CASSETTE": INPUT "PREPARATIONS ARE MADE.";XX$: PRINT "LOADING.": RECALL XX
671 FOR I = 1 TO LO: IF OB$(I) = "" THEN 674
672 OB(I,0) = XX(I,0)
673 OB(I,1) = XX(I,1)
674 NEXT I:CP = XX(LO +1,0)
710 GOTO 100
720 IF VB < >10 THEN 740
730 GOTO 1520
740 IF VB < >11 THEN 770
750 IF NO = 0 THEN PRINT "SAY WHAT?": GOSUB 1800: GOTO 140
760 PRINT "OKAY. IF IT IS REALLY NECESSARY...": GOSUB 1800: GOTO 140
770 IF VB < >12 THEN 810
780 IF NO < >12 THEN PRINT "I DON'T DO STUPID THINGS.": GOSUB 1800: GOTO 140
790 IF OB(12,0) < > -1 THEN PRINT "I DON'T HAVE ANY COKE TO DRINK!": GOSUB 1800: GOTO 140
800 PRINT M3$:OB(12,0) = 0:OB(13,0) = -1: GOSUB 1800: GOTO 140
810 IF VB < >13 THEN 880
820 IF OB(31,0) < > -1 THEN PRINT "BUT I HAVE NO FOOD!!": GOSUB 1800: GOTO 140
830 IF OB(NO,0) < >CP THEN PRINT "I DON'T SEE IT.": GOSUB 1800: GOTO 140
840 IF NO = 10 THEN PRINT "THE HYDRA WHARFS DOWN THE FOOD.":OB(31,0) = 0:OB$(10) = "A GIANT HYDRA RUBBING HIS STOMACH": GOSUB 1800: GOTO 140
850 IF NO = 20 THEN PRINT "THE BUGS IN THESE CAVES ONLY EAT HUMAN FLESH.": GOSUB 1800: GOTO 140
860 IF NO < >3 THEN PRINT "YOU CAN'T BE SERIOUS.": GOSUB 1800: GOTO 140
870 PRINT "IT REFUSES TO EAT THE FOOD.": GOSUB 1800: GOTO 140
880 IF VB < >14 THEN 960
890 IF NO = 10 AND OB(33,0) = CP THEN PRINT "THE UNDERTAKER JUST TOOK HIM AWAY.":OB(33,0) = 0: GOSUB 1800: GOTO 140
900 IF OB(NO,0) < >CP AND OB(NO,0) < > -1 THEN PRINT "I DON'T SEE IT AND I'M NOT HOLDING IT, SO HOW CAN I HIT IT?": GOSUB 1800: GOTO 140
910 IF NO = 3 THEN PRINT "NO!!! I KIND OF LIKE THE PARROT! POLLY WANT A CRACKER?"
920 IF NO = 10 THEN PRINT "OKAY... THE HYDRA GRUNTS >>DAMN MOSQUITOS<<"
930 IF NO = 20 THEN PRINT "YUCH! I DON'T WANT TO TOUCH!!!"
940 IF NO = 3 OR NO = 10 OR NO = 20 THEN GOSUB 1800: GOTO 140
950 PRINT "OKAY... OUCH! I HURT MY HAND!": GOSUB 1800: GOTO 140
960 IF VB = 15 THEN PRINT "I CAN'T KILL ANYTHING, I'M TOO WEAK. BUT MAYBE IF YOU WERE MORE SPECIFIC...": GOSUB 1800: GOTO 140
970 IF VB < >16 THEN 1060
980 IF OB(33,0) = CP AND NO = 10 THEN PRINT "IT IS ALREADY BURNT TO A CRISP.": GOSUB 1800: GOTO 140
990 IF OB(6,0) < > -1 THEN PRINT "I DON'T HAVE A LIGHTER OR MATCHES!!": GOSUB 1800: GOTO 140
1000 IF NO = 3 THEN PRINT "NEVER!! YOU KNOW SOMETHING, YOU'RE A SADIST.": GOSUB 1800: GOTO 140
1010 IF NO = 10 AND OB(10,0) = CP THEN OB(10,0) = 0:OB(33,0) = CP: PRINT "THE HYDRA CRUMBLES TO THE GROUND DEAD.": GOSUB 1800: GOTO 140
1020 IF NO = 20 THEN PRINT "THE BUG CANNOT BE BURNED. ": GOSUB 1800: GOTO 140
1030 IF NO = 10 THEN OB(10,0) = 0
1040 PRINT "IT DOESN'T BURN."
1050 GOSUB 1800: GOTO 140
1060 IF VB = 17 THEN PRINT "AND JUST WHO DO YOU THINK I AM, ROCKY??": GOSUB 1800: GOTO 140
1070 IF VB = 18 THEN PRINT "I DON'T KNOW HOW TO LIGHT THINGS. IF YOU WANT ME TO BURN SOMETHING, TELL ME SO!": GOSUB 1800: GOTO 140
1080 IF VB < >19 THEN 1170
1090 IF NO$ = "COIN" THEN NO$ = "QUARTER":NO = 7
1100 IF NO = 0 THEN PRINT "I DON'T KNOW WHAT ONE IS.": GOSUB 1800: GOTO 140
1110 IF NO = 7 THEN 1130
1120 IF OB(NO,0) < > -1 THEN PRINT "I'M NOT HOLDING IT RIGHT NOW.": GOSUB 1800: GOTO 140
1130 IF CP < >27 THEN PRINT "I DON'T SEE ANY COKE MACHINES HERE.": GOSUB 1800: GOTO 140
1140 IF NO < >7 THEN PRINT "THAT IS RIDICULOUS.": GOSUB 1800: GOTO 140
1150 IF OB(NO,0) < > -1 THEN PRINT "I HAVE NO MONEY.": GOSUB 1800: GOTO 140
1160 IF OB(7,0) = -1 AND CP = 27 THEN PRINT "ALL RIGHT. CHICKLIK CHINGGGG! A COKE POPPED OUT. THERE IS NOW A BOTTLE OF COKE HERE.":OB(7,0) = 0:NT = NT -1:OB(12,0) = 27: GOSUB 1800: GOTO 140
1170 REM
1180 IF VB < >21 THEN 1260
1190 IF NO < >18 AND OB(NO,0) = -1 THEN PRINT "IT'S KIND OF HEAVY, YOU KNOW.": GOSUB 1800: GOTO 140
1200 IF OB(NO,0) < > -1 THEN PRINT "FIRST YOU HAVE TO HELP ME FIND IT, DUMMY!": GOSUB 1800: GOTO 140
1210 IF CP = 10 OR CP = 11 THEN 1230
1220 PRINT "NOTHING HAPPENED.": GOSUB 1800: GOTO 140
1230 IF CP = 10 THEN CP = 11: GOTO 1250
1240 CP = 10
1250 GOTO 100
1260 IF VB = 23 THEN VB = 1: GOTO 140
1270 IF VB = 24 THEN PRINT "TRY 'KILL "NO$"'.": GOSUB 1800: GOTO 140
1280 IF VB < >25 THEN 1310
1290 IF NO = 21 THEN PRINT "NOTHING HAPPENED.": GOSUB 1800: GOTO 140
1300 PRINT "SIR WHAT??? I DON'T UNDERSTAND!": GOSUB 1800: GOTO 140
1310 IF VB < >26 THEN 1380
1320 IF CP = 1 AND OB(14,0) = -1 AND OB(22,0) = 1 THEN PRINT "OKAY!!!": GOTO 1510
1330 IF CP < >1 THEN PRINT "I CAN'T.": GOSUB 1800: GOTO 140
1340 IF VB < >26 THEN 1380
1350 IF OB(14,0) < > -1 THEN PRINT "I CAN'T. I HAVE NO TOOLS.": GOSUB 1800: GOTO 140
1360 PRINT "I CAN'T. I DON'T SEE THE FRIBULATING GONKULATOR AROUND ME.": IF OB(22,0) = -1 THEN PRINT "I THINK I HAVE TO DROP IT FIRST."
1370 GOSUB 1800: GOTO 140
1380 IF VB < >27 THEN 1460
1390 IF NO = 0 THEN PRINT "WHAT THE DEVIL IS A "NO$"??": GOSUB 1800: GOTO 140
1400 IF NO = 20 OR NO = 10 THEN IF OB(NO,0) = CP THEN PRINT "YUCH!!! I'D NEVER EAT A "NO$"!!!": GOSUB 1800: GOTO 140
1410 IF NO = 10 AND OB(33,0) = CP THEN PRINT "WELL...IT'S COOKED NOW, BUT IT STILL LOOKS RATHER GROSS.": GOSUB 1800: GOTO 140
1420 IF OB(NO,0) < > -1 THEN PRINT "I'M NOT HOLDING IT.": GOSUB 1800: GOTO 140
1430 IF NO = 3 AND OB(3,0) = -1 THEN PRINT "I'D RATHER NOT. I DON'T CARE FOR PARROT MEAT.": GOSUB 1800: GOTO 140
1440 IF NO = 31 AND OB(31,0) = -1 THEN NT = NT -1: PRINT "MMMM! IT WAS FILET MIGNON, MY FAVORITE DISH.":OB(31,0) = 0: GOSUB 1800: GOTO 140
1450 PRINT "I THINK THAT "OB$(NO)" WOULD GIVE": PRINT "ME INDIGESTION, AND I DON'T HAVE ANY PEPTO-BISMOL.": GOSUB 1800: GOTO 140
1460 IF VB < >30 THEN 1500
1470 IF CP < >10 AND CP < >11 THEN PRINT "NOTHING HAPPENED.": GOSUB 1800: GOTO 140
1480 PRINT "NICE TRY, BUT THAT'S AN OLD, WORN OUT MAGIC WORD."
1490 GOSUB 1800: GOTO 140
1500 PRINT "I DON'T KNOW HOW TO DO THAT.": GOSUB 1800: GOTO 140
1510 FOR I = 1 TO 1000: NEXT I
1520 PRINT "OUT OF A MAXIMUM OF 175 POINTS, YOU HAVESCORED ";:J = 0
1530 FOR I = 1 TO LO: IF OB(I,0) = 1 THEN J = J +OB(I,1)
1540 NEXT I
1550 PRINT J" POINTS."
1560 IF J = 175 THEN PRINT "ALL OF ADVENTUREDOM PAYS TRIBUTE TO YOU,ADVENTURER GRANDMASTER!": GOTO 1640
1570 IF J >165 THEN PRINT "YOUR SCORE PUTS YOU IN MASTER ADVENTURERCLASS 'A'.": GOTO 1640
1580 IF J >150 THEN PRINT "YOUR SCORE PUTS YOU IN MASTER ADVENTURERCLASS 'B'.": GOTO 1640
1590 IF J >140 THEN PRINT "YOU HAVE REACHED A 'JUNIOR MASTER' STATUS.": GOTO 1640
1600 IF J >120 THEN PRINT "YOU MAY NOW CONSIDER YOURSELF A 'SEASONED ADVENTURER'.": GOTO 1640
1610 IF J >110 THEN PRINT "YOU HAVE ACHIEVED THE RATING: 'EXPERIENCED ADVENTURER'.": GOTO 1640
1620 IF J >100 THEN PRINT "YOUR SCORE QUALIFIES YOU AS A 'NOVICE CLASS' ADVENTURER.": GOTO 1640
1630 PRINT "YOU ARE OBVIOUSLY A RANK AMATEUR. BETTER LUCK NEXT TIME."
1640 PRINT : INPUT "DO YOU WANT TO PLAY AGAIN? ";AG$:AG$ = LEFT$(AG$,1): IF AG$ = "N" THEN HOME : END
1645 IF AG$ < >"Y" THEN 1520
1650 FOR K = 1 TO LEN(NA$): POKE 24576 +K, ASC( MID$ (NA$,K,1)): NEXT K: POKE 24576 +K,191
1660 CLEAR :CO = 0:NA$ = ""
1670 CO = CO +1:PE = PEEK(24576 +CO): IF PE < >191 THEN NA$ = NA$ + CHR$(PE): GOTO 1670
1680 GOTO 20
1690 PRINT "GADZOOKS!!! A GIANT BUG JUST WALKED IN TO KILL ME!!!"
1700 FF = 1
1710 GOSUB 1800
1720 IF NO$ = "SESAME" AND VB$ = "OPEN" THEN PRINT "THE BUG HAS SHRUNKEN TO ITS PROPER SIZE AND SCURRIED AWAY.": GOTO 1780
1730 IF NO < >20 OR VB < >15 THEN PRINT "HELP ME!!! I'M BEING DEVOURED BY A GIANTBUG!!! THE END IS NEAR! OW!! THIS HURTS!I'M DYING...DYING...DEAD.": GOTO 1510
1740 IF OB(2,0) < > -1 THEN NO = 2: PRINT "I DON'T HAVE A SWORD!!!": GOTO 1730
1750 IF SW = 8 THEN PRINT "MY SWORD IS DULL, REMEMBER???":NO = 2: GOTO 1730
1760 PRINT "DING! DONG! THE BUG IS DEAD! THE BUG IS DEAD!!"
1770 SW = SW +1: IF SW = 8 THEN PRINT "MY SWORD IS DULL NOW."
1780 GOSUB 1800: GOTO 140
1790 END
1800 PRINT : PRINT "ENTER YOUR COMMAND -->";:CM$ = ""
1801 GET GT$: IF ASC(GT$) = 13 THEN 1809
1802 IF ASC(GT$) < >8 THEN 1807
1803 IF LEN(CM$) < = 1 THEN CM$ = "": GOTO 1808
1804 CM$ = LEFT$(CM$, LEN(CM$) -1): GOTO 1808
1807 CM$ = CM$ +GT$
1808 PRINT GT$;: GOTO 1801
1809 PRINT
1810 IF CM$ = "ABRA CADABRA" AND F5 <3 AND FF = 1 THEN NO$ = "SESAME":VB$ = "OPEN":FF = 0:F5 = F5 +1: RETURN
1820 VB$ = "":NO$ = "":VB = 0:NO = 0
1830 LC = LEN(CM$): FOR I = 1 TO LC: IF MID$ (CM$,I,1) < >" " THEN VB$ = VB$ + MID$ (CM$,I,1): NEXT I
1840 FOR I = 1 TO NV: IF VB$(I) = VB$ THEN VB = I: GOTO 1860
1845 NEXT I
1850 VB = 0:NO$ = VB$: GOTO 1880
1860 IF LEN(VB$) +1 > LEN(CM$) THEN NO = 0: RETURN
1870 NO$ = RIGHT$(CM$, LEN(CM$) -1 - LEN(VB$))
1880 FOR I = 1 TO NN: IF NO$(I) = NO$ THEN 1900
1885 NEXT I
1890 NO = 0: RETURN
1900 NO = I: RETURN
1910 PRINT P$(CP): PRINT
1920 FOR I = 1 TO LO: IF OB(I,0) = CP THEN PRINT "THERE IS "OB$(I)" HERE."
1930 NEXT I
1940 PRINT "I CAN GO : ";:F2 = 0
1950 FOR I = 1 TO 4: IF P(CP,I) < >0 THEN PRINT NO$(I +22)" ";:F2 = 1
1960 NEXT I: IF F2 = 0 THEN PRINT "NOWHERE!": GOTO 1970
1965 PRINT
1970 IF CP = 18 AND OB(3,0) = -1 THEN PRINT : PRINT M1$
1980 IF INT( RND(1) *35) = 5 AND CP < >1 AND CP < >37 AND CP < >27 THEN PRINT : GOTO 1690
1990 IF FD >4 THEN PRINT : PRINT "IF YOU'D LIKE, YOU CAN MAKE IT EASIER ONYOURSELF BY TYPING N, S, E, OR W INSTEAD OF NORTH, SOUTH, ETC.":FD = 0
2000 RETURN
2010 NP = 37: DIM P$(NP)
2030 P$(1) = "I'M ON A SHIP. A COMPUTER SCREEN HERE SAYS: 'SHIP WILL NOT FUNCTION, FRIBULATING GONKULATOR IS BURNED OUT.' IT'S OBVIOUS THAT THE SHIP HAS CRASHED."
2040 DATA 2,6,5,4:P$(2) = "I'M IN A COBBLESTONE HALLWAY. I CAN HEARCHIRPING NEARBY, SOUNDS LIKE BUGS...": DATA 8,1,3,5
2050 P$(3) = "I'M IN A DARK ROOM...OH NO!!! THERE ARE GIANT BUGS ALL AROUND ME!!!": DATA 0,0,0,2
2060 P$(4) = "I'M IN A SMALL ROOM. A SCRIBBLING HERE SAYS: 'HAR HAR HAR! YOU'LL NEVER MAKE IT! >> ARBADAC ARBA <<'": DATA 7,0,1,0
2070 P$(5) = "I'M IN A DUSTY COBBLESTONE HALLWAY.": DATA 0,25,2,1
2080 P$(6) = "I'M IN A DUSTY PLACE. IT IS VERY DARK INHERE. I'M SCARED!": DATA 1,24,0,0
2090 P$(7) = "I'M IN A LOW CRAWL SPACE. IT SEEMS AS IFWE'RE NOT SUPPOSED TO BE HERE...": DATA 0,4,15,0
2100 P$(8) = "I'M IN A ROOM WITH ROCK WALLS. IMBEDDED IN THE WALLS ARE SCATTERED RUBIES.": DATA 9,2,0,13
2110 P$(9) = "I'M IN A DARK ROOM. THIS ONE IS NOT SO SCARY. I THINK I HEAR GRUNTS AND GROANS NEARBY.": DATA 10,8,23,0
2120 P$(10) = "I'M ON THE SOUTH SIDE OF A CHASM. MOLTENLAVA IS BENEATH ME.": DATA 11,9,0,0
2130 P$(11) = "I'M ON THE NORTH SIDE OF THE CHASM.": DATA 16,10,0,0
2140 P$(12) = "I'M IN A MAZE OF TWISTY PASSAGES.": DATA 12,12,13,14
2150 P$(13) = P$(12): DATA 13,13,8,12
2160 P$(14) = P$(12): DATA 14,15,12,14
2170 P$(15) = P$(12): DATA 14,15,15,7
2180 P$(16) = "I'M ON A WOOD PLATFORM. A SIGN WARNS: 'GO BACK! GO SOUTH!!' THERE IS A RICKEDYBRIDGE TO THE NORTH.": DATA 17,11,0,0
2190 P$(17) = "I'M IN A DUSTY PASSAGE. A SIGN POINTS EAST AND SAYS: 'TO TROLLS PLACE -->' A RICKEDY BRIDGE EXTENDS SOUTHWARD. MARKINGS IN THE DUST INDICATE THAT SOMEONE WAS HERE RECENTLY.": DATA 0,16,18,0
2200 P$(18) = "A VOICE BOOMS OUT: 'WHO DARES TO ENTER MY PALACE???' (SOUNDS LIKE A TROLL TO ME!)": DATA 0,0,19,0
2210 P$(19) = "I'M IN THE TROLL'S PALACE. IT'S BREATH- TAKING!! THE CEILING IS SO HIGH, I CAN'TEVEN SEE IT!": DATA 0,20,0,0
2220 P$(20) = "I'M AT ONE END OF A SECRET PASSAGE.": DATA 119,0,0,21
2230 P$(21) = "I'M IN A SECRET PASSAGE.": DATA 21,22,20,21
2240 P$(22) = P$(21): DATA 21,22,22,23
2250 P$(23) = P$(21): DATA 23,23,22,9
2260 P$(24) = "I'M IN A HUGE ICE CAVERN. THE CEILING AND WALLS ARE COMPLETELY ICE.": DATA 6,26,25,0
2270 P$(25) = "I'M IN A ROOM WITH MANY ANIMALS... WAIT! THEY'VE ALL RUN AWAY.": DATA 5,0,0,0
2280 P$(26) = "I AM IN A ROOM WITH TRACES OF SLIME ON THE FLOORS AND WALLS.": DATA 24,29,27,28
2290 P$(27) = "I'M IN...AL'S DINER?!? THERE'S A COKE MACHINE HERE. IT SAYS: 'ENJOY COCA-COLA.25 CENTS (NO CANADIAN COINS PLEASE)'.": DATA 0,0,0,26
2300 P$(28) = "I'M IN A HUGE PIT.": DATA 0,0,26,0
2320 P$(29) = "I'M IN THE HYDRA ROOM. THE WALLS ARE ALLSLIME. BOY, I'VE NEVER SEEN ANYTHING SO GROSS IN MY LIFE!": DATA 26,30,31,32
2330 P$(30) = "I'M IN THE DRAGON ROOM. IT SEEMS TO BE DECORATED WITH DRAGONS.": DATA 29,34,0,33
2340 P$(31) = "I'M IN A TORTURE CHAMBER. LET'S GET OUT OF HERE QUICK!!": DATA 31,31,31,29
2350 P$(32) = "THIS IS THE CLAM ROOM. THE WALLS ARE SOLID CLAMSHELL EMBEDDED IN LIMESTONE.": DATA 0,0,29,0
2360 P$(33) = "I'M IN A MAMMOTH GARDEN FULL OF PLANTS.": DATA 0,0,30,0
2370 P$(34) = "I'M IN THE VELVET ROOM. THE WALLS AND CEILING ARE VELVET.": DATA 30,34,35,0
2380 P$(35) = "I'M IN AN ARABIAN ROOM WITH GUITARS PLAYING NEARBY. THERE IS AN OIL SLICK HERE. LOOKS LIKE MACHINE OIL, 10-W-30.": DATA 36,37,0,34
2390 P$(36) = "I'M IN THE TREASURE ROOM. MANY DWARVES GUARD SOME PETTY TREASURE. NOTHING TO FLIP OVER, ANYWAY.": DATA 0,35,0,0
2400 P$(37) = "I'M AT MAC'S EARTH-DIGGER BODY SHOP.": DATA 35,0,0,0
2410 DIM P(37,4): FOR I = 1 TO 37: FOR J = 1 TO 4: READ P(I,J): NEXT J,I
2420 LO = 33: DIM OB$(LO),OB(LO,1)
2425 DIM XX(LO,1)
2430 OB$(1) = "A SET OF KEYS": DATA 6,0:OB$(2) = "A SHINY SWORD": DATA 16,0
2440 OB$(3) = "A PARROT IN A CAGE": DATA 25,5:OB$(4) = "A GOLD NUGGET": DATA 4,10
2450 OB$(5) = "A 35,000 KARAT DIAMOND": DATA 7,10:OB$(6) = "A CIGARETTE LIGHTER": DATA 28,0
2460 OB$(7) = "A QUARTER": DATA 28,0:OB$(8) = "AN ENORMOUS EMERALD": DATA 32,15
2470 OB$(9) = "SOME SILVER BARS": DATA 33,15:OB$(10) = "A GIANT HYDRA": DATA 29,0
2480 OB$(11) = "A MING VASE": DATA 30,10:OB$(12) = "A BOTTLE OF COKE": DATA 0,0
2490 OB$(13) = "AN EMPTY COKE BOTTLE": DATA 0,0:OB$(14) = "SOME TOOLS": DATA 34,0
2500 OB$(15) = "A LARGE RUBY": DATA 8,15:OB$(16) = "SOME GOLD BARS": DATA 19,20
2510 OB$(17) = "A DIAMOND NECKLACE": DATA 19,25:OB$(18) = "A MAGIC WAND": DATA 14,0
2520 OB$(22) = "A FRIBULATING GONKULATOR": DATA 37,50
2530 OB$(20) = "A GIANT BUG, ASLEEP": DATA 31,0
2540 OB$(31) = "SOME TASTY FOOD":OB$(32) = "SOME HUMAN SKELETONS":OB(32,0) = 31:OB(32,1) = 0
2550 OB$(33) = "A DEAD HYDRA ON THE GROUND"
2560 FOR I = 1 TO 20: READ OB(I,0),OB(I,1): NEXT I
2570 OB(22,0) = OB(19,0):OB(22,1) = OB(19,1)
2580 OB(19,1) = 0:OB(19,0) = 0
2590 OB(31,0) = 27:OB(31,1) = 0
2600 DATA KEYS,SWORD,PARROT,NUGGET,DIAMOND,LIGHTER,QUARTER,EMERALD,SILVER,HYDRA,VASE,COKE,BOTTLE,TOOLS,RUBY,GOLD,NECKLACE,WAND,SIGN,BUG,ALEXANDER,GONKULATOR,NORTH,SOUTH,EAST,WEST
2610 DATA N,S,E,W,FOOD,SKELETONS
2620 NN = 32: DIM NO$(NN)
2630 FOR I = 1 TO NN: READ NO$(I): NEXT I
2640 DATA GO,GET,LOOK,INVEN,SCORE,DROP,HELP,SAVE,LOAD,QUIT,SAY,DRINK,FEED,HIT,KILL,BURN,FIGHT,LIGHT,INSERT,TAKE,WAVE,RELEASE,CONTINUE,DESTROY,SIR,FIX,EAT,?,INVENTORY,HOCUS
2650 NV = 30: DIM VB$(NV): FOR I = 1 TO NV: READ VB$(I): NEXT I
2660 M1$ = "THE PARROT CHANTS: 'SIR ALEXANDER...SIR ALEXANDER!'"
2670 M2$ = "THE TROLL SCURRIES AWAY IN FEAR."
2680 M3$ = "GULP GULP GULP! (BURP) - THAT WAS REFRESHING!"
2690 DIM H$(NP)
2700 H$(25) = "THIS PARROT TALKS..."
2710 H$(29) = "CIGAR? CIGARETTE? TIPPARILLO?"
2720 H$(10) = "YOU KNOW, THIS WORLD IS ENCHANTED..."
2730 H$(12) = "YOU CAN MAKE THE PASSAGES LOOK LESS ALIKE BY DROPPING THINGS."
2740 H$(13) = H$(12):H$(14) = H$(12):H$(15) = H$(12)
2750 H$(1) = "I THINK WE'RE SUPPOSED TO LEAVE WHAT WE FIND HERE."
2760 H$(35) = "OFTEN TIMES, OIL MEANS AN AUTO BODY SHOPIS NEARBY."
2770 H$(31) = "THE BUG WILL NOT BOTHER YOU. IT IS ASLEEP. HINT: IF YOU LINGER TOO LONG IN THIS ROOM, IT WILL WAKE UP!"
2780 H$(2) = "YOU KNOW, IN THIS ENCHANTED WORLD, MANY THINGS THAT ARE SMALL ON EARTH ARE VERY LARGE..."
2790 H$(20) = "TRY TO FIND YOUR WAY TO THE OTHER END, DUMMY!!!":H$(23) = H$(20)
2800 RETURN

Text found in Apple_II_Compilation_007_19xx__.do/DUKEDOM.bas:

1000 TEXT : HOME
1001 DEF FN X(Y) = RND(1) *(1 +F3% -( -F3%)) +( -F3%) +R(Y)
1002 GOSUB 20000
1010 GOTO 1620
1030 DIM P(8),L(3),G(10),S(6),U(6),R(8),P$(8),L$(3),G$(10)
1050 Q3% = RND(1) *(1 +Q2% -Q1%) +Q1%: IF Q3% >5 THEN G0% = Q3% +Q3%/2
1055 IF Q3% <5 THEN G0% = Q3%
1060 RETURN
1330 INPUT " ";V$:V$ = LEFT$(V$,1): IF LEN(V$) = 0 THEN V$ = "N"
1331 IF ABS( VAL(V$)) >95 THEN V$ = CHR$( ABS( VAL(V$) -32))
1332 IF V$ = "N" OR V$ = "Y" THEN RETURN
1333 PRINT "PLEASE ANSWER YES OR NO: ";: GOTO 1330
1335 IF ABS( VAL(V$)) >95 THEN V$ = CHR$( ABS( VAL(V$) -32))
1430 INPUT " ";V$:V = INT( VAL(V$)): IF V > = 0 THEN RETURN
1432 PRINT "PLEASE ENTER A NON-NEGATIVE NUMBER: ";: GOTO 1430
1530 PRINT "BUT YOU DON'T HAVE ENOUGH GRAIN": PRINT "YOU HAVE ";G;" HL. OF GRAIN LEFT,": IF X1 > = 4 THEN PRINT "ENOUGH TO BUY "; INT(G/X1)" HA. OF LAND"
1531 PRINT "ENOUGH TO PLANT "; INT(G/2);" HA. OF LAND": RETURN
1550 PRINT "BUT YOU DON'T HAVE ENOUGH LAND ": PRINT "YOU ONLY HAVE ";L;" HA. OF LAND LEFT ": RETURN
1570 : PRINT "BUT YOU DON'T HAVE ENOUGH PEASANTS": PRINT "YOUR PEASANTS CAN ONLY PLANT ";4 *P" HA. OF LAND": RETURN
1620 PRINT : PRINT "D U K E D O M ": PRINT "DO YOU WANT INSTRUCTIONS ? ";: GOSUB 1330: IF V$ = "N" THEN 2050
1690 HOME : PRINT "FOR INSTRUCTIONS ON THE GAME PLEASE READ CREATIVE COMPUTING, FEB. 1980 FOR THE LONG EXPLANATION OF THE HISTORICAL SITUATION BEHIND THE GAME."
1691 PRINT : PRINT "THE MOST IMPORTANT THING TO KNOW AT THIS POINT IS THE AMOUNT OF GRAIN NECESSARY TO FEED THE PEASANTS. 14 HL. PER PEASANT IS ADEQUATE. "
1692 PRINT "13 HL. PER PEASANT WILL CAUSE SOME HUNGER AND DECREASE FIGHTING ABILITY. AT 12 HL. PER, SOME WILL STARVE AND IT WILL CREATE RESENTMENT."
1693 PRINT "BY OVER FEEDING THE PEASANTS (UP TO 18) YOU WILL INCREASE THEIR GOOD WILL FOR YOU AND THEY WILL FIGHT BETTER FOR YOU IN THE COMING SPRING."
1694 PRINT "GOOD LUCK"
1700 INPUT " ";V$
2050 F3% = 2:M = 1.3: REM M IS CHANGED FROM 1.95..THIS CHANGE ALLOWS GREATER L(3) SPOILS OF WAR
2051 M = 1.95
2100 PRINT "DO YOU WISH TO SKIP THE DETAILED REPORTS AT THE END OF EACH YEAR? ";: GOSUB 1330:R$ = V$
2180 READ Y%,C1,U1,U2,K%,D,P,L,G
2190 FOR I = 1 TO 8: READ P(I): NEXT : FOR I = 1 TO 3: READ L(I): NEXT : FOR I = 1 TO 10: READ G(I): NEXT : FOR I = 1 TO 6: READ S(I): NEXT
2192 FOR I = 1 TO 8: READ P$(I): NEXT : FOR I = 1 TO 3: READ L$(I): NEXT : FOR I = 1 TO 10: READ G$(I): NEXT
2200 RESTORE
2210 DATA 0,3.95,0,0,0,0,100,600 ,4177,96,0,0,0,0,0,-4,8,600, 0,0,5193,-1344,0,-768,0,0,0, 1516,-120,-300,216,200,184,0 ,0,0
2270 Q1% = 4:Q2% = 7: GOSUB 1050:R(1) = G0%:Q2% = 8: GOSUB 1050:R(2) = G0%:Q2% = 6: GOSUB 1050:R(3) = G0%:Q1% = 3:Q2% = 8: GOSUB 1050:R(4) = G0%:Q1% = 5: GOSUB 1050:R(5) = G0%:Q1% = 3:Q2% = 6: GOSUB 1050:R(6) = G0%
2271 Q2% = 8: GOSUB 1050:R(7) = G0%:Q1% = 4: GOSUB 1050:R(8) = G0%
2460 PRINT "YEAR ";Y%;" PEASANTS "; INT(P);" LAND ";L;" GRAIN ";G: PRINT
2500 IF R$ = "Y" THEN 2810
2501 PRINT "YIELD = ";C;" HL/HA."
2510 FOR J1 = 1 TO 8: IF P(J1) < >0 OR J1 = 1 THEN PRINT P$(J1); TAB( 20); INT(P(J1))
2520 NEXT J1
2530 PRINT "PEASANTS AT END "; TAB( 20); INT(P)
2600 FOR J1 = 1 TO 3: IF L(J1) < >0 OR J1 = 1 THEN PRINT L$(J1); TAB( 20); INT(L(J1))
2610 NEXT J1: PRINT "LAND AT END "; TAB( 20); INT(L)
2690 PRINT "100% 80% 60% 40% 20% DEPL"
2691 PRINT "-----------------------------------"
2692 FOR J1 = 1 TO 6: IF J1 = 1 THEN GG = -5
2693 GG = GG +6: HTAB GG: PRINT INT(S(J1));: NEXT :
2694 PRINT
2720 FOR J1 = 1 TO 10: IF G(J1) < >0 OR J1 = 1 THEN PRINT G$(J1); TAB( 20); INT(G(J1))
2730 NEXT J1: PRINT "GRAIN AT END"; TAB( 20);G:
2800 IF Y% < = 0 THEN PRINT "(CROP DAMAGE DUE TO SEVEN YEAR LOCUSTS)"
2810 Y% = Y% +1: FOR I = 1 TO 8:P(I) = 0: NEXT : FOR I = 1 TO 3:L(I) = 0: NEXT : FOR I = 1 TO 10:G(I) = 0: NEXT
2815 P(1) = P:L(1) = L:G(1) = G
2816 PRINT
2980 IF P > = 33 THEN 3040
2981 PRINT "YOU HAVE SO FEW PEASANT LEFT THAT "
3000 PRINT "THE HIGH KING HAS ABOLISHED YOUR DUCAL RIGHT ": GOSUB 24040: GOTO 30000
3040 IF L > = 199 THEN 3070
3050 PRINT "YOU HAVE SO LITTLE LAND LEFT THAT ";: GOTO 3100
3070 IF U1 >88 OR U2 >99 THEN 3100
3071 IF G > = 429 THEN 3130
3100 PRINT "THE PEASANTS TIRE OF WAR AND STARVATION": PRINT "YOU ARE DEPOSED": PRINT : GOTO 30000
3130 IF Y% >45 AND K% = 0 THEN PRINT "YOU HAVE REACHED THE AGE OF MANDATORY RETIREMENT": GOTO 30000
3170 U1 = 0: IF K% >0 THEN PRINT "THE KING DEMANDS TWICE TH ROYAL TAX IN THE HOPE OF PROVOKING WAR. WILL YOU PAY";: GOSUB 1330:K% = 2: IF V$ = "N" THEN K% = -1
3270 PRINT "GRAIN FOR FOOD = ";: GOSUB 1430:V = V *P: IF V >G THEN GOSUB 1530: GOTO 3270
3271 IF V = 0 THEN 3270
3350 IF V/P <11 AND V 4)::U1 = U1 -3 *P(2) -2 *X1: IF V1 >88 THEN 3100
3491 IF P <33 THEN 2980
3580 C = C1:
3582 X1 = INT(2 *C + FN X(1) -5)
3585 X1 = -X1 *(X1 > = 4) -4 *(X1 <4)
3589 X1 = -X1
3640 PRINT "LAND TO BUY AT ";X1;" HL./HA.= ";: GOSUB 1430:G(3) = -V *X1: IF -G(3) >G THEN GOSUB 1530: GOTO 3640
3700 L(2) = V:S(3) = S(3) +V: IF V >0 THEN 4020
3701 X2 = S(1) +S(2) +S(3)
3740 FOR J1 = 1 TO 3:X1 = X1 -1: PRINT "LAND TO SELL AT ";X1;" HL./HA. = ";: GOSUB 1430: IF V >X2 THEN PRINT "BUT YOU ONLY HAVE "X2;" HA. OF GOOD LAND": GOTO 3840
3810 G(3) = V *X1: IF G(3) < = 4000 THEN 3870
3811 PRINT "NO BUYERS HAVE THAT MUCH GRAIN--SELL LESS"
3840 NEXT J1: PRINT "BUYERS HAVE LOST INTEREST":V = 0:G(3) = 0
3870 L(2) = -V
3880 FOR J1 = 3 TO 1 STEP -1: IF V < = S(J1) THEN 4010
3881 V = V -S(J1):S(J1) = 0: NEXT J1
3882 REM LOOP SHOULD NEVER EXIT HERE
3960 PRINT "LAND SELLING LOOP ERROR ": END
4010 S(J1) = S(J1) -V
4020 L = L +L(2): IF L <10 THEN 3040
4021 IF L(2) <0 AND X1 <4 THEN G(3) = INT(G(3)/2): PRINT "THE HIGH KING APPROPRIATES HALF YOUR EARNINGS AS PUNISHMENT FOR SELLING AT JUST A LOW PRICE!!"
4090 G = G +G(3)
4130 IF K% < > -2 THEN 4350
4131 PRINT "THE KING'S ARMY IS ABOUT TO ATTACK YOUR DUCHY":X1 = INT(G/100): PRINT "AT 100 HL EACH (PAYMENT IN ADVANCE)"
4170 PRINT "YOU HAVE HIRED ";X1;" FOREIGN MERCENARIES": IF 8 *X1 +P >2399 THEN 4220
4190 PRINT "THE PLACEMENT OF YOUR HEAD ATOP THE CASTLE GATE SIGNIFIES THAT ";: GOTO 3000
4220 PRINT "WIPE THE BLOOD FROM THE CROWN--YOU ARE NOW HIGH KING!": PRINT "A NEARBY MONARCHY THREATENS WAR": PRINT "HOW MANY......": GOSUB 24040: GOTO 32767
4349 PRINT "TOTAL LAND THAT PEASANTS CAN PLANT";4 *P
4350 PRINT "TOTAL LAND PEASANTS CAN PLANT "; INT(4 *P): PRINT "**LAND TO PLANT = ";: GOSUB 1430: IF V >L THEN GOSUB 1550: GOTO 4350
4360 IF V >4 *P THEN GOSUB 1570: GOTO 4350
4430 G(4) = -2 *V: IF -G(4) >G THEN GOSUB 1530: GOTO 4350
4470 G(8) = V:G = G +G(4)
4500 FOR I = 1 TO 6:U(I) = 0: NEXT
4510 FOR J1 = 1 TO 6: IF V < = S(J1) THEN 4620
4511 V = V -S(J1):U(J1) = S(J1):S(J1) = 0: NEXT J1
4600 PRINT "LAND TABLE UPDATING ERROR": END
4620 U(J1) = V:S(J1) = S(J1) -V:S(1) = S(1) +S(2):S(2) = 0
4660 FOR J1 = 3 TO 6:S(J1 -2) = S(J1 -2) +S(J1):S(J1) = 0: NEXT J1
4700 FOR J1 = 1 TO 5:S(J1 +1) = S(J1 +1) +U(J1): NEXT :S(6) = S(6) +U(6)
4710 HOME
4770 C = FN X(2) +3
4775 IF INT(Y%/7) *7 = Y% THEN PRINT "SEVEN YEAR LOCUSTS":C = C/2
4830 X1 = 0: FOR J1 = 1 TO 5:X1 = X1 +U(J1) *(1.2 -.2 *J1): NEXT J1: IF G(8) = 0 THEN C1 = 0:C = 0:
4831 IF G(8) < >0 THEN C1 = INT((C *(X1/G(8))) *100)/100:C = C1
4920 PRINT "YIELD = ";C;" HL./HA.":X1 = FN X(3) +3
4921 IF X1 <9 THEN GOTO 5190
4922 IF X1 > = 9 THEN G(5) = - INT((X1 *G)/83):G = G +G(5)
4990 PRINT "RATS INFEST THE GRAINERY": IF P <67 OR K% = -1 THEN 5190
4991 X1 = INT( FN X(4))
4992 IF X1

70 THEN 5195
5194 GOTO 5230
5195 HOME : GOSUB 24040: VTAB 4: PRINT "TODAY IS YOUR LUCKY DAY.....": VTAB 10: PRINT "YOU HAVE JUST DISCOVERED MERLIN THE MAGICIAN YOUR OLD FRIEND. HE SEES THE TERRIBLE SHAPE YOUR DUCHY IS IN AND HE OFFERS YOU ONE OF THESE GIFTS:"
5197 PRINT : PRINT "(1) 50 EXTRA PEASANTS (2) 200 MORE HA. OF LAND (3) 4000 MORE HL. OF GRAIN ": PRINT : PRINT "WHICH DO YOU CHOSE?": GET AN$:ANS = VAL(AN$): IF ANS = 0 OR ANS >3 THEN 5197:
5199 IF ANS = 1 THEN P = P +50
5200 IF ANS = 2 THEN S(1) = S(1) +200:L = L +200:
5202 IF ANS = 3 THEN G = G +4000
5204 GOTO 5230
5220 REM
5230 IF K% = -1 THEN PRINT "THE HIGH KING CALLS FOR PEASANT LEVIES AND HIRES MANY FOREIGN MERCENARIES":K% = -2: GOTO 6340
5240 X1 = INT(20 -1.5 *C): IF K% < >0 OR P < = 109 OR 17 *(L -400) +G < = 10600 THEN 5350
5241 PRINT "THE HIGH KING GROWS UNEASY AND MAY BE SUBSIDIZING WARS AGAINST YOU.":X1 = X1 +2:X2 = Y% +5: GOSUB 24000: GOTO 5380
5350 X2 = 0
5380 X3 = FN X(5): IF X3 >X1 THEN 6340
5381 PRINT "A NEARBY DUKE THREATENS WAR ";:X2 = INT(X2 +85 +18 + FN X(6)): GOSUB 20020
5440 X4 = INT(1.2 -U1/16):X5 = INT(P *X4) +13: PRINT "WILL YOU ATTACK FIRST ? ";: GOSUB 1330: IF V$ = "N" THEN 5590
5441 IF X2 >X5 THEN 5540
5442 PRINT "PEACE NEGOTIATIONS WERE SUCCESSFUL"
5510 P(4) = -X1 -1:X2 = 0: GOTO 5570
5540 PRINT "FIRST STRIKE FAILED-YOU NEED PROFESSIONALS":P(4) = -X3 -X1 -2:X2 = X2 +3 *P(4)
5570 P = P +P(4)
5571 IF X2 <1 THEN U1 = U1 -2 *P(4) -3 *P(5): GOTO 6340
5590 PRINT "HOW MANY MERCENARIES WILL YOU HIRE AT 40 HL. EACH = ";: GOSUB 1430:
5640 X2 = INT(X2 *M):X5 = INT(P *X4) +7 *V +13:X6 = X2 -4 *V - INT(.25 *X5):X2 = X5 -X2:L(3) = INT(.8 *X2): IF -L(3) >.67 *L THEN PRINT "YOU HAVE BEEN OVERRUN AND HAVE LOST THE ENTIRE DUKEDOME": GOTO 4190
5720 X1 = L(3)
5730 FOR J1 = 1 TO 3:X3 = INT(X1/(4 -J1)): IF -X3 < = S(J1) THEN X5 = X3
5731 IF -X3 >S(J1) THEN X5 = -S(J1)
5790 S(J1) = S(J1) +X5:X1 = X1 -X5: NEXT J1
5820 FOR J1 = 4 TO 6: IF -X1 < = S(J1) THEN X5 = X1
5821 IF -X1 >S(J1) THEN X5 = -S(J1)
5870 S(J1) = S(J1) +X5:X1 = X1 -X5
5871 NEXT J1
5900 IF L(3) <399 THEN 6010
5910 PRINT "YOU HAVE OVERRUN THE ENEMY AND ANNEXED HIS ENTIRE DUKEDOM":G(7) = 10000:G = G +G(7):X6 = -47:X4 = .55: GOSUB 24050: IF K% >0 THEN 6130
5970 K% = 1: PRINT "THE KING FEARS FOR HIS THRONE AND MAY BE PLANNING DIRECT ACTION": GOSUB 24040: GOTO 6130
6010 IF X2 > = 0 THEN PRINT "YOU HAVE WON THE WAR":X4 = .67:G(7) = INT(20 *L(3)):G = G +G(7): GOTO 6090: REM THIS HAS BEEN CHANGED TO INCREASE FRUITS OF WAR
6070 PRINT "YOU HAVE LOST THE WAR":X4 = G(8)/L
6090 IF X6 < = 9 THEN X6 = 0
6091 IF X6 >9 THEN X6 = INT(X6/10)
6130 X6 = -X6 *(X6 < = P) -P *(X6 >P):P(4) = -(P(4) -X6):P = P +X6:G(8) = G(8) + INT(X4 *L(3)):X6 = 40 *V
6131 IF X6 < = G THEN G(6) = -X6: GOTO 6250
6132 IF X6 >G THEN G(6) = -G
6133 P(5) = INT((X6 -G)/7) -1: PRINT "THERE ISN'T ENOUGH GRAIN TO PAY THE MERCENARIES!!!!"
6250 G = G +G(6):P(5) = -P(5) *( -P(5) < = P) +P *( -P(5) >P):P = P +P(5):L = L +L(3):U1 = U1 -2 *P(4) -3 *P(5)
6255 P(5) = INT(P(5)):P = INT(P)
6340 X1 = FN X(7):X1 = INT(X1): REM BELONG?:P(6)= 0
6341 IF X1 >2 THEN 6500
6342 IF X1 < >1 THEN 6440
6343 IF D >0 THEN 6500
6344 PRINT "THE BLACK PLAGUE HAS STRUCK THE AREA":D = 13:X2 = 3: GOSUB 23000
6430 P(6) = - INT(P/X2):P = P +P(6): GOTO 6500
6440 PRINT "A POX EPIDEMIC HAS BROKEN OUT":X2 = X1 +5:P(6) = - INT(P/X2):P = P +P(6)
6500 X1 = FN X(8) +4
6501 X1 = -X1 *(P(5) = 0) -4.5 *(P(5) < >0):P(8) = - INT(P/X1):P(7) = INT(.3 -P/22):P = P +P(7) +P(8):D = D -1
6600 G(8) = INT(C *G(8)):G = G +G(8):X1 = G(8) -4000
6601 G(9) = -(X1 < = 0) + INT(.1 *X1) *(X1 >0):G(9) = -(G(9) +120):G = G +G(9)
6670 IF K% <0 THEN 6790
6671 X1 = INT(L/2)
6710 IF K% > = 2 THEN X1 = X1 * -2
6713 IF K% <2 THEN X1 = X1 * -1
6720 IF -X1 >G THEN PRINT "YOU HAVE INSUFFICIENT GRAIN TO PAY THE ROYAL TAX": GOTO 3000
6740 G(10) = X1:G = G +X1
6790 U2 = INT(U2 *.85) +U1: GOSUB 24030: GOTO 2270
7000 DATA "PEASANTS AT START","STARVATIONS","KING'S LEVY", "WAR CASULTIES", "LOOTING VICTIMS","DISEASE VICTIMS","NATURAL DEATHS","BIRTHS"
7100 DATA "LAND AT START", "BOUGHT/SOLD", "FRUITS OF WAR"
7200 DATA "GRAIN AT START","USED FOR FOOD","LAND DEALS","SEEDINGS", "RAT LOSSES", "MERCENARY HIRE", "FRUITS OF WAR", "CROP YIELD", "CASTLE EXPENSE","ROYAL TAX"
20000 POKE 770,173: POKE 771,48: POKE 772,192: POKE 773,136: POKE 774,208: POKE 775,5: POKE 776,206: POKE 777,1: POKE 778,3
20010 POKE 779,240: POKE 780,9: POKE 781,202: POKE 782,208: POKE 783,245: POKE 784,174: POKE 785,0: POKE 786,3: POKE 787,76: POKE 788,2: POKE 789,3: POKE 790,96: POKE 791,0: POKE 792,0: RETURN
20020 K = 10
20030 FOR J = 1 TO 10
20040 H = 50
20050 FOR X = 1 TO 5
20060 H = H +1
20070 POKE 768,H: POKE 769,K: CALL 770
20080 POKE 768,50: POKE 769,9: CALL 770
20090 NEXT : NEXT
20100 RETURN
23000 FOR J = 1 TO 10
23010 H = 255
23020 FOR X = 1 TO 5
23030 H = H -10
23040 POKE 768,H: POKE 769,10: CALL 770
23050 NEXT : NEXT
23060 RETURN
24000 FOR K = 1 TO 8: FOR X = 1 TO 4: IF X <2 THEN I = 75:
24010 IF X >2 THEN I = 149
24020 J = 8: POKE 768,I: POKE 769,J: CALL 770: NEXT X: NEXT K: RETURN
24030 J = 100:I = 15: FOR K = 1 TO 10: POKE 768,J: POKE 769,I: CALL 770: NEXT K: RETURN
24040 FOR X = 1 TO 5:I = 120:J = 75: POKE 768,I: POKE 769,J: CALL 770:I = 140: POKE 768,I: POKE 769,J: CALL 770: NEXT X: RETURN
24050 FOR X = 1 TO 10:I = 60:J = 10: POKE 768,I: POKE 769,J: CALL 770:I = 90: POKE 768,I: POKE 769,J: CALL 770: NEXT X: RETURN
30000 PRINT : PRINT "DO YOU WISH TO TRY ANOTHER GAME ? ";: GOSUB 1330: IF V$ = "Y" THEN 2180
32767 END

Text found in Apple_II_Compilation_007_19xx__.do/HELLO.bas:

10 TEXT : HOME : NORMAL
62500 D$ = CHR$(4)
62502 PRINT ""
62505 TEXT : HOME : NORMAL : PRINT D$;"CATALOG":B = PEEK(27) -2: IF B >22 THEN B = 22
62510 T = 0:CH = 4: FOR CV = 0 TO 23: GOSUB 62640: IF C < >160 THEN POKE P -1,219: POKE P,T +193: POKE P +1,221:T = T +1:S = CV
62520 NEXT CV: VTAB 24:A$ = "TYPE LETTER TO RUN, OR LOAD=1 LOCK=2 UNLOCK=3 DELETE=4 EXIT=5...."
62530 B$ = "RUN": HTAB 1: PRINT LEFT$(A$,39);:A$ = MID$ (A$,2) + LEFT$(A$,1):K = PEEK( -16384): IF K <128 THEN FOR K = 1 TO 75: NEXT K:K = FRE(0): GOTO 62530
62540 POKE -16368,0:K = K -176: IF K <1 OR K >5 THEN 62610
62550 HTAB 1: CALL -868: IF K = 5 THEN END
62560 PRINT " PRESS 'LETTER' YOU WISH TO ";: IF K = 1 THEN B$ = "LOAD"
62570 IF K = 2 THEN B$ = "LOCK"
62580 IF K = 3 THEN B$ = "UNLOCK"
62590 IF K = 4 THEN B$ = "DELETE": FLASH
62600 PRINT B$;: CALL -198: NORMAL : GET K$:K = ASC(K$) -48
62610 IF K <17 OR K >T +16 THEN 62530
62620 CH = 1:CV = S -T +K -16: GOSUB 62640: IF C = 194 AND (B$ = "RUN" OR B$ = "LOAD") THEN B$ = "B" +B$
62630 FOR CH = 6 TO 39: GOSUB 62640:B$ = B$ + CHR$(C): NEXT CH: HTAB 1: CALL -868: PRINT B$: PRINT D$;B$: GOTO 62500
62640 C1 = INT(CV/8):C2 = CV -C1 *8:P = 1024 +128 *C2 +40 *C1 +CH:C = PEEK(P): RETURN

Text found in Apple_II_Compilation_007_19xx__.do/IMHOTEP.bas:

20 TEXT : HOME : GR : GOSUB 1200:NN = 0
50 READ B$:P = 300000:D = 2500:S = 330:T = 0:W = 0:ER = 0:N = 0:IM$ = "IMHOTEP"
60 TEXT : HOME : GOSUB 61: GOTO 70
61 PRINT TAB( 20)"*": PRINT TAB( 19)"***": PRINT TAB( 18)"*****": PRINT TAB( 17)"*******": PRINT TAB( 16)"*********": PRINT : PRINT : RETURN
70 PRINT TAB( 17)"IMHOTEP": PRINT TAB( 13)"PYRAMID BUILDER": PRINT : PRINT
75 PRINT "WRITTEN BY: TERRY CLARK": PRINT "TRANSLATED TO APPLE BY: M.P. ANTONOVICH": PRINT : PRINT : GOSUB 61
80 FOR I2 = 1 TO 5000: NEXT I2: HOME
85 PRINT "++++A DECREE FROM ZOSER,": PRINT " THE GOLDEN HORUS,": PRINT " BULL OF KHEM.++++"
90 PRINT : PRINT "TO IMHOTEP,MASTER MASON"
100 PRINT "IMHOTEP,THE PHAROAH HAS COMMANDED A","PYRAMID TO BE BUILT. THE HORUS DESIRES","THIS GLORY TO HIS NAME TO BE FINISHED","WITHIN A PERIOD OF TWELVE YEARS."
130 PRINT "YOUR OVERSEER IS ";B$: PRINT "HE IS TO OBEY YOUR COMMANDS.": PRINT : PRINT
140 PRINT "HIT ANY KEY TO CONTINUE ";: GET A$
141 HOME
142 IF T = 0 THEN 163
145 GOSUB 690
150 VTAB 21: PRINT "WORK SITE AFTER ";T;" YEARS"
161 GOSUB 162: GOTO 163
162 FOR I1 = 1 TO 3000: NEXT I1: RETURN
163 TEXT : HOME
164 PRINT "POPULATION OF KHEMI - "; INT(P)
165 PRINT "PHAROAH OWNS "; INT(S);" GRAIN STOREHOUSES.": PRINT "NILE FLOODED "; INT(D);" TELS OF LAND."
180 PRINT : PRINT "# OF PEOPLE YOU WISH ON WORK FORCE": INPUT W
190 IF (W >P) OR (W <0) THEN 780
200 PRINT : PRINT "FROM "; INT(S);" STOREHOUSES OWNED BY RA,"
210 INPUT "HOW MANY WILL FEED WORKERS ";I
220 IF (I >S) OR (I <0) THEN 810
230 P = P -W:S = S -I
250 PRINT : PRINT "FROM "; INT(S);" REMAINING STOREHOUSES,"
260 PRINT "HOW MANY WILL FEED "; INT(P): INPUT " REMAINING PEOPLE ";J
270 IF (J >S) OR (J <0) THEN 820
280 S = S -J
290 PRINT : PRINT "FROM "; INT(D);" TELS, HOW MANY DO YOU"
300 INPUT "WISH TO PLANT ";B
320 IF B >D OR B <0 THEN 840
330 IF B >S *100 THEN 870
340 IF B >P *10 THEN 880
350 TEXT : HOME :H = 0: GOSUB 61
360 M = I *1000: IF M -W >0 THEN M = W
370 L = J *1000:R = L -P: IF R <0 THEN R = 0
380 R = R + INT( RND(1) *1000)
385 IF P -L >0 THEN PRINT "YOU HAVE STARVED ";P -L;" PEOPLE.":ER = ER +1
386 IF L -P >0 THEN L = P
390 IF P -L >P *.45 THEN 900
400 U = INT( RND(1) *40): IF U <4 THEN 1050
401 IF (M -W) <0 THEN PRINT " YOU HAVE STARVED ";W -M;" WORKERS.":ER = ER +2: GOTO 1050
410 Z = INT( RND(1) *50): IF (Z <9) AND (N >4) THEN 1130
420 K = RND(1) *3.5:S = S -(B/100)
430 IF N >T *2 THEN ER = ER -1
440 IF ER > = 0 THEN O = INT(((S *( RND(1)) +(ER *4))/2)): IF O <2 THEN S = S -0
450 IF ER <0 THEN O = INT(S *( RND(1))/10):S = S +0
460 IF S <0 THEN S = 0
470 S = S +((B *K)/10):T = T +1
480 D = INT( RND(1) *4000 +(O *.5)):Q = RND(1) *30: IF Q >22 THEN 950
481 IF (Q >12) AND (Q <18) THEN 1010
482 IF Q <8 THEN 920
490 WA = RND(1) *300: IF WA <19 THEN GOSUB 940
491 IF WA >282 THEN GOSUB 1040
492 IF (WA <210) AND (WA >165) THEN GOSUB 960
493 IF (A >75) AND (WA <130) THEN GOSUB 1020
494 IF (WA >255) AND (WA <260) THEN GOSUB 1030
510 PRINT "THE HARVEST THIS YEAR WAS ";K/10: PRINT "STOREHOUSES PER TEL."
520 IF ER > = 0 THEN 530
521 IF (ER <0) AND (O >1) THEN PRINT "THE PRIESTS OF AMEN GAVE ZOSER,";O: PRINT " STOREHOUSES OF GRAIN.":H = H +1: GOTO 540
530 IF O <2 THEN GOTO 540
531 IF ER > = 0 THEN PRINT O;" STOREHOUSES OF GRAIN WERE CLAIMED": PRINT " BY THE PRIESTS OF AMEN.":H = H +1
540 PRINT "THE POPULATION INCREASED BY ";R: PRINT " PEOPLE."
550 P = R +L +M -U1 -V1
551 U1 = 0:V1 = 0
560 N = INT(N +(W -(W -M))/90000)
570 IF N >20 THEN N = 20
580 IF (N <21) AND (N >0) THEN PRINT "THE WORK FORCE HAS COMPLETED ";N: PRINT "COURSES OF THE PYRAMID."
590 IF (N <21) AND (D <1000) AND (H <10) THEN PRINT "THE VIZIERS PREDICT A POOR FLOOD NEXT ","YEAR.":H = H +2
591 IF (N <21) AND (D >3700) AND (H <10) THEN PRINT "THE MELTING SNOW OF ETHIOP WELLS THE","NILE THIS SPRING.":H = H +2
600 IF (N <10) AND (T >6) OR (ER >3) AND (N <20) THEN PRINT "PHAROAH IS BOTHERED BY YOUR INEFFICIENCY":H = H +2
610 IF ER >7 THEN PRINT "HE HAS DECREED, THAT FOR YOUR MISTAKES,","YOU WILL BE EXILED TO THE RED LAND OF","THE EAST.": GOTO 660
620 IF H <2 THEN PRINT IM$;",": PRINT "AN UNEVENTFUL YEAR."
621 IF (H >8) AND (H <14) THEN PRINT IM$;",": PRINT "A VERY EVENTFUL YEAR."
624 PRINT "HIT ANY KEY TO CONTINUE ";: GET A$
625 IF T = 6 THEN GOSUB 1330
630 GOSUB 690
640 IF T > = 13 THEN 890
650 S = INT(S *10 +5)/10:D = INT(D *10 +.5)/10:P = INT(P *10 +.5)/10: GOTO 150
660 PRINT "IMHOTEP WILL YOU TRY AGAIN? (Y/N) ";: GET V$
661 IF V$ = "Y" THEN RUN
662 IF V$ = "N" THEN TEXT : HOME : END
670 GOTO 660
690 HOME : GR : GOSUB 1200: COLOR= 13:E = 0:F = 39:Y = 39
691 IF N = 0 THEN RETURN
692 IF NN >0 THEN FOR G = 1 TO NN: HLIN E,F AT Y:E = E +1:F = F -1:Y = Y -1: NEXT G
693 FOR G = NN +1 TO N: FOR EE = E TO F
694 PLOT EE,Y:SD = PEEK( -16336) + PEEK( -16336): FOR PA = 1 TO 10: NEXT PA: NEXT EE
695 E = E +1:F = F -1:Y = Y -1: NEXT G
696 NN = N
750 IF N = 20 THEN 970
760 RETURN
780 PRINT IM$;",": PRINT "ZOSER HEARD YOUR FOOLISHNESS.": PRINT "HE HAS EXILED ";B$;".":ER = ER +1
790 ONERR GOTO 1190
800 READ B$: PRINT B$;" HAS BEEN ASSIGNED AS OVERSEER.": PRINT "NOW...": GOTO 180
810 PRINT IM$;",": PRINT "DO NOT JEST,": PRINT "THE HAWK'S EARS ARE SHARP.":ER = ER +1: GOTO 200
820 PRINT IM$;",": PRINT "I, ";B$;", WARN YOU NOT":ER = ER +1
830 PRINT "TO MOCK PHAROAH ZOSER, HIS FLAIL IS","SWIFT.": GOTO 250
840 PRINT IM$;",": PRINT "PHAROAH HAS KILLED ";B$: PRINT "YOUR OVERSEER.":ER = ER +1
850 ONERR GOTO 1190
860 READ B$: PRINT "I AM ";B$;" YOUR NEW OVERSEER.": PRINT " NOW....": GOTO 290
870 PRINT "THERE IS ONLY ENOUGH GRAIN TO PLANT ";S *100 -1: PRINT " TELS.":ER = ER +1: IF S *100 -1 <0 THEN 901
871 GOTO 290
880 PRINT "THERE ARE ONLY ENOUGH PEOPLE TO PLANT ": PRINT P *10;" TELS.":ER = ER +1: GOTO 290
890 PRINT "YOU HAVE RUN OUT OF TIME, ZOSER WANTS","YOUR HEAD.": GOTO 660
900 REM YOU KILLED TOO MANY PEOPLE
901 PRINT "ZOSER WANTS YOU MUMIFIED ALIVE IN THE ","HOUSE OF THE DEAD.": GOTO 660
920 Q = RND(1) *(P/2) *5:Q = INT(Q +.5): PRINT "A PESTILENCE DESCENDED FROM AMEN-RE.":H = H +1
930 PRINT Q;" PEOPLE DIED.":V1 = Q: GOTO 510
940 Q = INT( RND(1) *P): PRINT "HYKSOS WITH CHARIOTS AND BLADES OF","BLACK EVIL METAL HAVE ATTACKED KHEM,",Q;" PEOPLE HAVE BEEN KILLED.":V1 = Q:H = H +3: RETURN
950 V = INT( RND(1) *50): PRINT "NUBIAN EMISSARIES HAVE BROUGHT TRIBUTE","OF "V" STOREHOURSES OF GRAIN.":S = S +V:H = H +2: GOTO 510
960 Q = INT( RND(1) *P): PRINT "ACHEAN BARBARIANS FROM THE NORTHERN SEA","HAVE RAIDED THE DELTA ";Q: PRINT "PEOPLE HAVE BEEN KILLED.":V1 = Q:H = H +3: RETURN
970 I2 = 2000
980 PRINT "IMHOTEP, YOU FULFILLED THE WISH": FOR I1 = 1 TO I2: NEXT I1
981 PRINT "OF PHAROAH. YOUR REWARD IS THE GREAT": FOR I1 = 1 TO I2: NEXT I1
982 PRINT "HONOR OF BEING ENTOMBED WITH YOUR LORD": FOR I1 = 1 TO I2: NEXT I1
983 PRINT "AND MASTER, ZOSER, THE GOLDEN HORUS.": FOR I1 = 1 TO I2: NEXT I1: GOTO 660
1010 V = INT( RND(1) *50): PRINT "A MILITARY CAMPAIGN LED BY ZOSER HAS","BROUGHT AN ADDITIONAL ";V;" TELS": PRINT "OF LAND INTO THE DOUBLE-KINGDOM.":D = D +V:H = H +3: GOTO 510
1020 V = INT( RND(1) *50 +20): PRINT "MINOAN MERCHANTS HAVE BROUGHT ";V: PRINT "STOREHOUSES OF GRAIN TO TRADE FOR": PRINT "METHODS OF BUILDING AS PRACTICED IN","KHEMI.":S = S +V:H = H +4: RETURN
1030 V = INT( RND(1) *100): PRINT "HTE PHAROAH'S NEW SYRIAN BRIDE BROUGHT","A WEDDING PRESENT OF ";V;" STOREHOUSES","OF GRAIN.":S = S +V:H = H +3: RETURN
1040 V = INT( RND(1) *W):V1 = V:W = W -V: PRINT "A FANATICAL REBEL-PRIEST HAS ESCAPTED","WITH ";V;" WORKERS INTO THE": PRINT "WILDERNESS OF THE SINAI.":H = H +3: RETURN
1050 IF W = O THEN RETURN
1060 U = INT( RND(1) *100): PRINT "THE WORK FORCE HAS REBELLED. ";U
1070 PRINT "WORKERS, AND ";B$;",THE OVERSEER,": PRINT "WERE KILLED BY"
1080 PRINT "PHAROAH'S VICTORIOUS ANUBIS SQUARDRON."
1090 U1 = U:W = W -U
1110 READ B$: PRINT "THE GREAT ZOSER HAS CHOSEN ";B$: PRINT "TO BE YOUR NEW OVERSEER.":H = H +6: GOTO 420
1130 Z = INT( RND(1) *2 +2):N = N -Z:W = W - INT(W *.25):M = W +P: IF NN >N THEN NN = N
1140 PRINT Z;" COURSES OF THE PYRAMID HAVE": PRINT "COLLAPSED AND ONE-FOURTH OF THE WORK","FORCE WAS LOST.":H = H +3: GOTO 420
1160 N = 20: GOTO 690
1180 DATA "MENE-PTAH","RA-ANX-TETA","ATUM-ATON","SETEP-EN-RE","RAMOSE","MERI-ATUM","KA-RES","MAATTUM","MERI-TEHU"
1181 DATA "TOTHMES","RE-MES-SES","PTAHMES","MERIPASHTU"
1200 COLOR= 9: HLIN 4,8 AT 1: HLIN 8,12 AT 2: PLOT 12,3: HLIN 7,8 AT 3
1202 VLIN 2,9 AT 6: VLIN 5,9 AT 7: VLIN 2,9 AT 5: VLIN 2,9 AT 4: VLIN 2,9 AT 3: VLIN 3,9 AT 2: PLOT 1,4
1203 HLIN 8,12 AT 9: HLIN 4,5 AT 19: HLIN 4,5 AT 20: HLIN 15,16 AT 20: HLIN 14,15 AT 19: HLIN 3,8 AT 21: HLIN 14,19 AT 21
1204 COLOR= 1: HLIN 13,15 AT 5: PLOT 15,6: VLIN 5,21 AT 13: VLIN 11,15 AT 2: VLIN 11,15 AT 39
1205 FOR ZP = 1 TO 6: PLOT 5 +ZP,9 +ZP: PLOT 3 +ZP,9 +ZP: NEXT ZP: PLOT 8,10
1206 FOR YP = 1 TO 3: FOR ZP = 1 TO YP *2 -1: PLOT 2 +ZP,16 +ZP -YP *2: NEXT ZP,YP
1207 COLOR= 3: HLIN 3,6 AT 16: HLIN 3,5 AT 17: HLIN 3,5 AT 18: HLIN 8,13 AT 16: HLIN 10,13 AT 17: HLIN 11,14 AT 18
1210 HLIN 28,31 AT 16: HLIN 27,30 AT 17: HLIN 27,29 AT 18: HLIN 35,38 AT 16: HLIN 35,38 AT 17: HLIN 35,37 AT 18
1211 COLOR= 9: HLIN 33,37 AT 1: HLIN 33,38 AT 2: HLIN 33,34 AT 3: HLIN 36,39 AT 3: HLIN 36,39 AT 4: HLIN 23,26 AT 21: HLIN 33,38 AT 21
1212 VLIN 5,9 AT 38: VLIN 5,9 AT 33: VLIN 4,8 AT 34: VLIN 6,8 AT 35: VLIN 7,9 AT 36: HLIN 27,33 AT 9: PLOT 32,8
1213 HLIN 27,30 AT 5: HLIN 30,31 AT 6: HLIN 31,32 AT 6: HLIN 26,28 AT 19: HLIN 25,26 AT 20: HLIN 36,37 AT 19: HLIN 36,37 AT 20
1214 COLOR= 1: FOR XP = 1 TO 6: PLOT 35 -XP,9 +XP: PLOT 37 -XP,9 +XP: PLOT 39 -XP,9 +XP: NEXT XP
1215 FOR XP = 1 TO 4: PLOT 39 -XP,11 +XP: NEXT XP: PLOT 38,14: PLOT 37,15
1220 VTAB 21: PRINT TAB( 16)"IMHOTEP"
1225 IF TZ = 1 THEN RETURN
1230 FOR ZZ = 0 TO 5000: NEXT ZZ:TZ = 1: RETURN
1330 TEXT : HOME : GOSUB 61: PRINT TAB( 16)"JUBILEE": PRINT "IT IS TIME FOR PHAROAH'S JUBILEE.","YOU HAVE USED HALF OF YOUR TIME."
1340 IF (N = 20) OR ((N >10) AND (P >300000) AND (S *1000 >P) AND (ER <2)) THEN PRINT IM$: PRINT "PHAROAH IS PLEASED WITH YOUR": PRINT "PERFORMANCE SO FAR AND BESTOWS A GREAT","HONOR ON YOU. FROM THIS MOMENT YOU ARE","KNOWN AS 'GREAT LORD IMHOTEP'."
1345 IF (N = 20) OR ((N >10) AND (P >300000) AND (S *1000 >P) AND (ER <2)) THEN ER = -1:IM$ = "GREAT LORD IMHOTEP": GOTO 1370
1350 IF (N <7) AND (ER >3) AND (P <300000) AND (S *1000 < = P +50) THEN PRINT IM$: PRINT "PHAROAH IS DISPLEASED WITH YOU AND","DESIRES FOR YOU TO SUFFER THE DISHONOR","OF BEARING THE TITLE 'IMHOTEP THE","INCOMPETENT'."
1355 IF (N <7) AND (ER >3) AND (P <300000) AND (S *100 < = P +50) THEN ER = ER +1:IM$ = "IMHOTEP THE INCOMPETENT": GOTO 1370
1360 PRINT IM$: PRINT "PHAROAH FEELS YOU HAVE NOT PUT FORTH A","GOOD EFFORT AND DESIRES TO REMIND YOU","OF YOUR RESPONSIBILITIES WITH THE","TITLE 'IMHOTEP-HORUS-WATCHES'.":IM$ = "IMHOTEP-HORUS-WATCHES"
1370 PRINT "HIT ANY KEY TO CONTINUE ";: GET A$: RETURN

Text found in Apple_II_Compilation_007_19xx__.do/INSPECTOR.CLOU.bas:

5 TEXT : CLEAR : HOME
10 DIM S$(5),R$(6),P(5,9),Q(9)
20 FOR D = 1 TO 9:Q(D) = INT( RND(1) *6 +1): NEXT
90 S$(1) = "BILL":S$(2) = "MARY":S$(3) = "PAUL":S$(4) = "SUZY":S$(5) = "JOHN"
100 R$(1) = "LOUNGE":R$(2) = "ATRIUM":R$(3) = "LIVING":R$(4) = "DINING":R$(5) = "TROPHY":R$(6) = "GARAGE"
103 GOTO 160
105 FOR AA = 1 TO 5: IF ZA$ < > LEFT$(S$(AA),1) THEN NEXT :PP = 0: RETURN
107 PP = AA: RETURN
120 ZA$ = LEFT$(ZA$,4): FOR AA = 1 TO 5: IF ZA$ < >S$(AA) THEN NEXT : GOTO 105
130 PP = AA: RETURN
140 ZA$ = LEFT$(ZA$,6): FOR AA = 1 TO 6: IF ZA$ < >R$(AA) THEN NEXT :PP = 0: RETURN
150 PP = AA: RETURN
160 HOME : VTAB 5: PRINT SPC( 4)"***** INSPECTOR CLOUSEAU *****": VTAB 9
210 PRINT "BILL, MARY, PAUL, SUZY, AND JOHN WERE","HOUSE GUESTS. THEIR HOST WAS MURDERED","BETWEEN THE HOURS OF 1 PM AND 9 PM."
220 PRINT "YOUR TASK IS TO DETERMINE THE KILLER,","TIME, AND ROOM LOCATION OF THE CRIME.","YOU HAVE A HOUSE DIAGRAM AND A LIST OF QUESTIONS FOR THE SUSPECTS. THE GUILTY PERSON MAY TRY TO MISLEAD YOU."
250 PRINT : PRINT "PRESS ANY KEY. ";: GET A$: HOME
260 PRINT "HOUSE DIAGRAM: O=WINDOWS"
310 H = 0:C = 0:C1 = 0: PRINT ",---------------------------,": PRINT "! ! TROPHY O !": PRINT "! DINING O ! GARAGE !": PRINT "! '---,- --! !"
320 PRINT "! !------!": PRINT "!--O----------! ! !": PRINT "! '--,": PRINT "! LIVING !- ----! !"
330 PRINT "! ,--' ! LOUNGE !": PRINT "'-, ! O !": PRINT " ' O ATRIUM ! ,---'": PRINT " '--------'---------'-----'"
350 PRINT : POKE 34, PEEK(37)
360 VTAB 1: HTAB 33: PRINT "SUSPECTS": FOR AA = 1 TO 5: HTAB 35: PRINT S$(AA): NEXT
400 HOME
460 FOR K = 1 TO 5:P(K,1) = INT(6 * RND(1)) +1: NEXT : FOR L = 2 TO 9: FOR K = 1 TO 5
510 A = INT(6 * RND(K)) +1: IF A = P(K,L -1) THEN 510
520 P(K,L) = A: NEXT : NEXT
580 M = INT(5 * RND(1)) +1:T = INT(9 * RND(2)) +1:R = P(M,T)
610 PRINT : INPUT "WHO WILL YOU QUESTION? ";S1$
615 IF LEFT$(S1$,6) = "SOLVED" OR RIGHT$(S1$,6) = "SOLVED" THEN 1200
620 ZA$ = S1$: GOSUB 120:S = PP: IF S = 0 THEN 610
630 HOME
640 PRINT "WHICH NUMBERED QUESTION WILL YOU ASK",S$(S)"?": PRINT : PRINT "1. WHEREABOUTS AND WHAT "S$(S)" SAW AT A"," CERTAIN TIME?",,"2. WHEN "S$(S)" WAS EVER IN A CERTAIN ROOM?"
650 VTAB 21
680 PRINT "3. YOU MAKE A CONFRONTATION BECAUSE"," PART OF THE CRIME IS NOW SOLVED.": PRINT : GET AX$: IF AX$ < >"1" AND AX$ < >"2" AND AX$ < >"3" THEN 630
690 A = VAL(AX$)
700 C = C +1: ON A GOTO 720,990,1200
720 HOME : PRINT S$(S)", WHERE WERE YOU AT PM?": VTAB PEEK(37): HTAB 25: GET TX$
730 VTAB PEEK(37) +1: HTAB 25: PRINT TX$
745 IF TX$ < >"1" AND TX$ < >"2" AND TX$ < >"3" AND TX$ < >"4" AND TX$ < >"5" AND TX$ < >"6" AND TX$ < >"7" AND TX$ < >"8" AND TX$ < >"9" THEN 720
747 T1 = VAL(TX$)
750 PRINT
760 R1 = P(S,T1): IF S < >M THEN 865
790 IF RND(2) <.7 THEN 865
800 R1 = INT(6 * RND(3)) +1: IF RND(3) >.16 THEN 865
810 PRINT "I WAS WITH OUR HOST.": IF RND(4) >T1 *.1 +.1 THEN 840
820 PRINT "OUR HOST WAS DEAD.": GOTO 910
840 PRINT "OUR HOST WAS STILL ALIVE.": GOTO 910
865 IF (T1 = T) AND R1 = R AND (S < >M OR (S = M AND RND(1) <.5)) THEN PRINT "I WAS WITH OUR HOST.",,"OUR HOST WAS DEAD."
910 PRINT "I WAS IN THE ";R$(R1);" ROOM."
920 FOR K = 1 TO 5: IF K = S THEN 960
940 IF P(K,T1) = R1 THEN PRINT "I WAS WITH "S$(K)"."
950 IF ABS(R1 -P(K,T1)) = 1 THEN PRINT "I SAW "S$(K)" THROUGH A WINDOW."
960 NEXT : GOTO 610
990 HOME : PRINT S$(S)", WHEN WERE YOU IN THE ROOM?": VTAB PEEK(37): HTAB (27): INPUT " ";ZA$:ZA$ = LEFT$(ZA$,6): VTAB PEEK(37): HTAB 35: PRINT "ROOM?"
1010 GOSUB 140:T1 = PP
1020 IF NOT T1 THEN 990
1025 PRINT
1030 IF S < >M THEN 1110
1040 IF RND(5) <.5 THEN 1110
1050 T1 = INT( RND(5) *6) +1
1090 PRINT "I WAS NEVER IN THAT ROOM.": GOTO 610
1110 K = 0: FOR B = 1 TO 9: IF P(S,B) = T1 THEN PRINT "I WAS IN THAT ROOM AT "B" PM.":K = 1
1120 NEXT : IF NOT K THEN PRINT "I WAS NEVER IN THAT ROOM."
1130 GOTO 610
1200 C1 = C1 +1
1205 HOME
1210 PRINT "IT IS TIME FOR THE CONFRONTATION.","INSPECTOR CLOUSEAU, WHAT HAVE YOU FOUND?"
1220 PRINT "1. THE KILLER.",,,"2. THE MURDER ROOM.",,"3. THE TIME OF THE MURDER.","4. YOU ARE TOTALLY BAFFLED AND GIVE UP.": PRINT : GET AX$: IF AX$ < >"1" AND AX$ < >"2" AND AX$ < >"3" AND AX$ < >"4" THEN 1205
1230 A = VAL(AX$): HOME
1260 ON A GOTO 1270,1420,1350,1550
1270 INPUT "WHO IS THE KILLER? ";ZA$: GOSUB 120: IF NOT PP THEN HOME : GOTO 1270
1280 IF PP < >M THEN PRINT : GOTO 1530
1285 VTAB M +2: HTAB 35: INVERSE : PRINT S$(M): NORMAL : HOME
1290 PRINT "YOU HAVE DETERMINED THE KILLER.":H = H +1: IF EG THEN PRINT : PRINT "INSPECTOR, YOU DO REMEMBER THAT YOU","DETERMINED THE KILLER EARLIER?":H = H -1
1295 EG = 1
1300 IF H = 7 THEN 1500
1340 GOTO 610
1350 HOME : PRINT "WHAT WAS THE TIME OF THE MURDER? ";: GET AX$: VTAB PEEK(37) +1: HTAB 34: PRINT AX$" PM."
1353 IF AX$ < >"1" AND AX$ < >"2" AND AX$ < >"3" AND AX$ < >"4" AND AX$ < >"5" AND AX$ < >"6" AND AX$ < >"7" AND AX$ < >"8" AND AX$ < >"9" THEN PRINT : GOTO 1350
1355 T1 = VAL(AX$)
1360 IF T1 < >T THEN PRINT : GOTO 1530
1370 PRINT
1380 PRINT "YOU DETERMINED THE CORRECT MURDER TIME.":H = H +2: IF RT THEN PRINT : PRINT "INSPECTOR, YOU DO REMEMBER THAT YOU","DETERMINED THE MURDER TIME EARLIER?":H = H -2
1385 RT = 1: PRINT :UI = PEEK(37): VTAB 9: HTAB 34: INVERSE : PRINT "TIME:"T1: NORMAL : VTAB UI
1390 IF H = 7 THEN 1500
1400 GOTO 610
1420 HOME : INPUT "WHERE WAS THE HOST MURDERED? ";ZA$: GOSUB 140: IF NOT PP THEN 1420
1430 IF PP < >R THEN PRINT : GOTO 1530
1435 VTAB 11: HTAB 34: INVERSE : PRINT R$(R): HTAB 35: PRINT "ROOM": NORMAL : HOME
1440 PRINT "YOU HAVE DETERMINED THE MURDER ROOM.":H = H +4: IF WS THEN PRINT : PRINT "INSPECTOR, YOU DO REMEMBER THAT YOU","DETERMINED THE MURDER ROOM EARLIER?":H = H -4
1450 WS = 1: IF H < >7 THEN 610
1500 FOR XT = 1 TO 3300: NEXT : HOME : PRINT "INSPECTOR CLOUSEAU, YOU SOLVED THE CASE.IT TOOK YOU "C" QUESTIONS AND "C1,"CONFRONTATIONS. YOUR RATING IS ";:RT = C * -25 +C1 *C1 * -25 +1000: PRINT RT"."
1505 IF RT > = 700 THEN PRINT "INSPECTOR, YOU ARE REALLY INCREDIBLE!": GOTO 1590
1510 IF RT > = 600 THEN PRINT "INSPECTOR, YOU ARE INCREDIBLE!": GOTO 1590
1515 IF RT > = 500 THEN PRINT "INSPECTOR, YOU ARE ALMOST AMAZING!": GOTO 1590
1517 IF RT > = 200 THEN PRINT "INSPECTOR, YOU ARE PRETTY GOOD!": GOTO 1590
1520 IF RT > = 0 THEN PRINT "FINE WORK, INSPECTOR.": GOTO 1590
1523 IF RT > = -1000 THEN PRINT "YOU FUMBLED THIS ONE, INSPECTOR.": GOTO 1590
1525 PRINT "THAT WAS REALLY STUPID WORK, INSPECTOR.": GOTO 1590
1530 PRINT "INSPECTOR CLOUSEAU, YOU ARE WRONG.": GOTO 610
1550 HOME : PRINT "YOU FUMBLED THIS ONE, INSPECTOR.": PRINT : PRINT "THE FACTS ARE: "S$(M)" KILLED THE HOST AT "T" O'CLOCK IN THE "R$(R)" ROOM."
1590 PRINT : INPUT "DO YOU WANT A NEW CASE? ";A$: IF A$ = "Y" OR A$ = "YES" THEN 5
1600 IF A$ < >"N" AND A$ < >"NO" THEN HOME : GOTO 1590
1610 TEXT : CLEAR : HOME

Text found in Apple_II_Compilation_007_19xx__.do/LOST.DUTCHMAN..bas:

10 POKE 34,0: POKE 35,24: TEXT : HOME
20 VTAB 5: PRINT " WELCOME TO THE SEARCH FOR THE LOST DUTCHMAN'S GOLD. I'M THE GHOST OF BACK-PACK SAM, YER GUIDE ON THIS ADVENTURE. YA CAN USE 2 WORD COMMANDS TO FIND CLUES'N MOVE 'BOUT. GET, GO, PUT, DROP,
30 PRINT "SCORE, INVENTORY 'N 'BOUT 100 MORE WORDSMAKE SENSE TA ME. ASK FER HELP IF YA GET STUMPED.": PRINT " I HOPE YA DON'T END UP A GHOST, LIKE ME!
35 REM
36 DIM N$(26,7),O$(32,3),R$(46):B = 0:IN = B:LN = 50:LM = LN:X1 = B:X2 = B:T$ = "":M1$ = T$:M2$ = T$:QM$ = T$:U = B:U1 = B:IM = 2:BD = 21:L = 1:C$ = CHR$(13): PRINT "MON C,I,O"
40 FOR L = B TO 26: FOR I = B TO 7: READ N$(L,I): NEXT I,L
50 FOR I = B TO 32: READ O$(I,0),O$(I,1),O$(I,2):O$(I,3) = "": NEXT
60 FOR I = B TO 46: READ R$(I): NEXT
70 PRINT "HIT 'SPACE' TO START.": GET QM$:L = 1: INPUT "RESTORE OLD GAME?";QM$: IF LEFT$(QM$ +" ",1) < >"Y" THEN 100
80 INPUT "NAME?";QM$:QM$ = "LDG/" +QM$: ONERR GOTO 4000
85 PRINT "VERIFY "QM$: PRINT "OPEN "QM$: PRINT "READ "QM$
90 INPUT L,CL,LN,IN,LM,U,U1,IM
91 FOR X = 0 TO 32: INPUT O$(X,1),O$(X,2),O$(X,3): NEXT
95 PRINT "CLOSE"QM$: POKE 216,0
100 IF ((O$(12,2) = STR$(L) OR O$(12,3) = "1") AND CL >0) OR L <15 THEN 150
102 POKE 34,0: POKE 35,23: HOME : PRINT "IT'S TOO DARK TA SEE !!": IF L = 15 AND O$(6,3) < >"1" AND O$(4,3) < >"1" THEN PRINT "YA HEAR A STRANGE NOISE !
110 POKE 35,24: GOTO 350
120 T$ = "OK": RETURN
140 B = 1: PRINT : PRINT "YA SEE : ";: RETURN
150 IF CL = 1 THEN LN = LN -1: IF LN <1 THEN CL = 0
160 I = FRE(00):L1 = L
170 B = 0: POKE 35,BD: POKE 34,0: VTAB 1: HOME : POKE 35,24: PRINT "YER "N$(L,0)".": FOR J = 0 TO 32: IF VAL(O$(J,2)) < >L THEN 240
175 IF B = 0 THEN GOSUB 140
180 IF O$(J,3) = "-7" OR O$(J,3) = "-2" THEN PRINT "BURNT ";
190 IF J < >1 OR VAL(O$(1,2)) < >L THEN 200
193 IF O$(1,3) = "" THEN PRINT "UNTIED ";: GOTO 200
196 IF O$(1,3) = "-9" THEN PRINT "DEAD ";
200 IF O$(J,3) = "-3" THEN PRINT "SMASHED ";
210 IF L < >26 OR J < >32 THEN 220
213 IF U1 < >0 THEN PRINT "UN";
216 PRINT "LOCKED ";
220 IF CL = 1 AND J = 12 THEN PRINT "LIT ";
230 PRINT O$(J,0)". ";
240 NEXT J
250 IF U1 = 1 AND L = 1 THEN PRINT "OPEN TRAP DOOR. ";
260 IF N$(L,1) = "" THEN PRINT : GOTO 330
265 IF B = 0 THEN GOSUB 140
270 IF L < >16 THEN 280
273 IF U < >0 THEN PRINT "UN";
276 PRINT "LOCKED ";: GOTO 290
280 IF L < >17 GOTO 290
283 IF U = 1 THEN PRINT "UNLOCKED ";: GOTO 290
286 PRINT "BLOCKED ";
290 PRINT N$(L,1)".
310 IF L = 17 AND U = 0 THEN N$(L,2) = " " + RIGHT$(N$(L,2),3)
320 IF L = 16 AND U = 1 THEN N$(L,2) = "E" + RIGHT$(N$(L,2),3)
330 CALL -868: PRINT : IF N$(L,2) = "" THEN 350
335 PRINT "OBVIOUS EXITS : ";: FOR I = 1 TO 4:P$ = MID$ (N$(L,2),I,1): IF P$ = "N" THEN PRINT "NORTH ";
336 IF P$ = "S" THEN PRINT "SOUTH ";
337 IF P$ = "E" THEN PRINT "EAST ";
338 IF P$ = "W" THEN PRINT "WEST ";
340 NEXT : CALL -868: PRINT
350 B = 0: PRINT "=======================================
360 BD = PEEK(37): POKE 34,BD: VTAB 24: IF L = 9 AND O$(22,2) = "11" THEN PRINT "THAR'S NOISE UP AHEAD.": PRINT "SOUNDS LIKE INJUNS.
370 IF L = 9 AND O$(22,2) = "" THEN O$(22,2) = "11
390 INPUT " --NOW WHAT?";QM$
410 IF LN <10 AND CL = 1 THEN PRINT "YER RUNNIN' LOW ON KEROSENE.
415 IF QM$ = "SAVE" OR QM$ = "SAVE GAME" THEN 2520
420 IF QM$ < >"SCORE" THEN 450
423 IF L < >6 THEN T$ = "YA GET NOTHIN' FOR BEIN' HERE!": GOTO 1900
426 Z = 0: FOR I = 14 TO 17: IF O$(I,2) = "6" THEN Z = Z +1
430 NEXT
440 PRINT "YA GOT "Z" TREASURES, TOT'LIN "(Z/4) *100"%": IF Z = 4 THEN PRINT "YA MADE IT!!": GOTO 2220
445 T$ = "YA MISSED SUM TREASURE!": GOTO 1900
450 IF CL = 0 AND L = 15 AND O$(6,3) < >"1" THEN PRINT "YE GAD!": PRINT "YA BEEN BIT BY A RATTLER.": PRINT "YER DEAD.": GOTO 2220
460 IF L = 17 AND U = 1 AND RND(1) *9 +1 <2 THEN PRINT "&(%]#&@ CAVE IN !! /:+*@": PRINT "THE IRON DOOR'S BLOCKED,": PRINT "YER TRAPPED!!":U = 0
480 IF QM$ = "HELP" THEN X = VAL(N$(L,3)): ON X GOSUB 2300,2310,2320,2330,2350,2370,2380,2390: GOTO 100
490 X1 = LEN(QM$): IF X1 <3 THEN T$ = "WHAT?": GOTO 1900
493 X3 = 0: FOR X2 = 3 TO X1:M1$ = MID$ (QM$,X2,1): IF M1$ = " " THEN X3 = X2:X2 = X1
495 NEXT X2:X2 = X3: IF X3 = 0 THEN X2 = X1
500 P$ = LEFT$(QM$,3): IF X2 < >X1 AND X2 +3 >X1 THEN 610
501 II = -1: FOR I = 0 TO 42: IF P$ = R$(I) THEN II = I
502 NEXT : IF II > -1 THEN I = II: GOTO 520
510 IF X1 = X2 THEN T$ = "WHAT?": GOTO 1900
511 T$ = "SORRY, BUT YA CAN'T " + LEFT$(QM$,X2): IF X2 -1 THEN 630
543 IF M1$ = "IRO" THEN 580
545 IF I = 36 THEN 940
550 IF N$(L,1) = "" THEN 560
552 Z = 1:A = Z:X1 = LEN(N$(L,1)): FOR X2 = 5 TO X1: IF MID$ (N$(L,1),X2,1) < > CHR$(46) AND X2 < >X1 THEN NEXT : GOTO 560
553 M2$ = MID$ (N$(L,1),Z,3): IF M2$ = M1$ THEN 556
554 Z = X2 +2:A = A +1: NEXT : GOTO 560
556 X2 = X1: NEXT :B = A: IF I = 10 THEN PRINT "YA SEE NOTHIN' SPECIAL.": GOTO 160
558 GOTO 630
560 FOR X = 43 TO 46: IF M1$ = R$(X) THEN X = 46: NEXT : GOTO 650
565 NEXT
570 IF O$(4,3) = "1" OR O$(6,3) = "1" THEN IF I = 23 AND M1$ = "SEL" THEN PRINT "OK": PRINT "YER DEAD.": GOTO 2220
580 IF I = 32 THEN GOSUB 780: GOTO 1900
590 IF I = 33 THEN GOSUB 860: GOTO 1900
600 T$ = "I CAN'T TELL WACHA WANT.": GOTO 1900
610 T$ = "I MUST BE DUMB, YA DON'T MAKE SENSE.": GOTO 1900
630 IF I <9 THEN 650
633 IF J <33 AND J > -1 THEN B = VAL(O$(J,2)): IF B < >L AND B >0 THEN 1890
636 IF J >32 THEN J = 29
640 ON I -8 GOSUB 1250,1390,1390,1390,1250,1700,1700,1700,1700,1820,1820,1250,700,700,1080,1060,1060,920,1150,1190,1210,730,730,780,860,1250,900,940,1700,1690,1320,1340,1820,2500
650 IF I <9 THEN ON I +1 GOSUB 970,970,970,2220,680,970,1920,2000,1320
660 GOTO 1900
680 IF O$(3,3) < >"1" THEN 1890
683 PRINT "OK": FOR I = 13 TO 17: IF VAL(O$(I,2)) = -L THEN T$ = "EUREKA! WE STRUCK GOLD?!??":O$(I,2) = STR$(L): RETURN
685 NEXT
686 T$ = "DAG NAB IT! THAR'S NOTHIN' HERE!": RETURN
700 IF J < >23 THEN 1060
701 IF L = 14 THEN O$(23,2) = "15": GOTO 120
702 IF L = 15 THEN O$(23,2) = "16": GOTO 120
703 IF L = 16 AND U = 1 THEN O$(23,2) = "17": GOTO 120
704 IF L = 17 THEN O$(23,2) = "19": GOTO 120
705 IF L = 19 THEN O$(23,2) = "23":O$(23,3) = "-3
710 GOTO 120
730 IF J = 3 OR J = 4 OR J = 6 OR J = 8 OR J = 9 OR J = 11 OR J = 12 OR J = 13 OR J = 19 OR J = 27 OR J = 28 THEN 740
735 GOTO 1050
740 IF O$(J,3) = "1" THEN IN = IN -1
750 O$(J,3) = "-3":O$(J,2) = STR$(L): GOTO 120
770 T$ = "DON'T HAVTA.": RETURN
780 IF L < >16 THEN 800
783 IF U < >0 THEN 770
786 IF O$(10,3) = "1" THEN U = 1: GOTO 120
788 GOTO 1890
800 IF L < >26 THEN 820
803 IF U1 < >0 THEN 770
806 IF O$(10,3) = "1" THEN U1 = 1: RETURN
808 GOTO 1890
820 IF O$(1,3) < >"1" THEN 840
825 IF O$(0,3) = "2" THEN O$(0,3) = "":O$(0,2) = STR$(L): GOTO 120
830 GOTO 1050
840 IF CL = 1 AND O$(12,3) = "1" THEN CL = 0: GOTO 120
860 IF (L = 16 OR L = 17) AND U = 1 THEN U = 0: GOTO 120
870 IF L = 26 AND U1 = 1 THEN U1 = 0: GOTO 120
880 GOTO 1050
900 T$ = "YA HEAR NOTHIN' SPECIAL.": RETURN
920 IF L < >11 OR O$(9,3) < >"1" THEN 1320
930 PRINT "THEY TOOK THE FIRE WATER 'N RAN.":IN = IN -1:O$(9,2) = "":O$(9,3) = "":O$(22,2) = "": RETURN
940 IF M1$ = "YOH" THEN T$ = "TURKEY!": PRINT "SORRY, YOUR IN THE WRONG ADVENTURE.": GOTO 1900
950 GOSUB 120:T$ = T$ + CHR$(13) + RIGHT$(QM$,X1 -X2) +".": GOTO 1900
970 IF B = 0 THEN 980
973 L = VAL(N$(L,B +3)): IF O$(1,3) = "1" AND (L = 1 OR L = 6 OR L = 15) THEN T$ = "HE WON'T GO.":L = L1: RETURN
976 IF L = 17 AND U = 0 THEN L = L1: GOTO 1890
978 IF L1 = 26 AND L = 1 AND U1 = 0 THEN L = L1: GOTO 1890
979 GOTO 1060
980 IF U1 = 1 AND L = 1 THEN L = 26: GOTO 120
990 IF U1 = 1 AND M1$ = "TRA" AND L = 26 THEN L = 1: RETURN
1000 FOR X1 = 1 TO 4:M2$ = MID$ (N$(L,2),X1,1): IF M2$ < > LEFT$(M1$,1) THEN NEXT X1: GOTO 1010
1003 FOR X2 = 43 TO 46: IF M1$ < >R$(X2) THEN NEXT X2: GOTO 1010
1006 L = VAL(N$(L,X1 +3)): IF L < >0 THEN 1060
1010 IF L = 23 THEN T$ = "IT'S TOO SLIPPERY.": RETURN
1020 IF L = 25 THEN L = 26: RETURN
1030 IF L = 26 THEN L = 25: RETURN
1040 IF L = 19 THEN L = 23: PRINT "NIGH BROKE M'NECK!!": RETURN
1050 T$ = "SORRY, BUTCHA CAN'T DO THAT.": RETURN
1060 B = 0: GOTO 120
1080 IF O$(4,3) < >"1" AND O$(6,3) < >"1" THEN 1320
1083 IF J < >1 THEN 1110
1086 Z = 0: IF O$(J,3) = "1" THEN Z = 99
1090 O$(J,3) = "-9":O$(1,2) = STR$(L)
1100 IF Z = 99 THEN IN = IN -1
1110 IF J = 22 THEN PRINT "YA GOT ONE!": PRINT "BUT THE REST GOT YOU!": GOTO 2220
1120 IF J = 9 THEN T$ = "YA HIT ONE!": RETURN
1130 GOTO 120
1150 IF O$(18,3) < >"1" THEN 1890
1152 IF J <0 THEN 511
1153 IF J = 4 OR (J >5 AND J <11) OR (J >14 AND J <18) OR J = 22 OR J = 29 OR J >30 THEN 1050
1156 IF O$(J,3) = "1" THEN IN = IN -1
1157 O4(J,3) = "-7":O$(J,2) = STR$(L)
1158 IF J >0 THEN 1060
1160 IF O$(0,3) < >"-7" THEN 1060
1163 O$(0,2) = STR$(L): FOR J = 5 TO 21: IF O$(J,2) = "-1" THEN O$(J,3) = "-7"
1170 NEXT : GOTO 1060
1190 IF J < >12 THEN 1150
1193 IF O$(J,3) < >"1" OR O$(18,3) < >"1" THEN 1150
1195 CL = 1: GOTO 120
1210 IF J = 13 THEN PRINT "YEEECH!!": PRINT "IT'S KEROSENE!": PRINT "YA JUST POISONED YERSELF.": GOTO 2220
1220 IF J < >9 THEN 1050
1230 PRINT "WHEEEE!!": PRINT "YA GOT PLASTERED AND LOST A DAY.": IF CL = 1 THEN LN = LN -10
1235 RETURN
1250 IF J >32 OR J <0 THEN 1260
1253 B = VAL(O$(J,2)): IF O$(J,3) = "2" OR B = L OR B = -1 THEN 1260
1255 IF J <22 THEN 1890
1257 T$ = "IT AIN'T HERE.": RETURN
1260 IF J >21 OR J = 1 OR J = -1 THEN T$ = "WHO THE HECK YA THINK YA IS?" +C$ +"PAUL BUNYON??! YA AIN'T STRONG 'NUF.": RETURN
1270 IF O$(J,3) = "-7" THEN T$ = "IT'S BURNT UP 'N RUINED.": RETURN
1280 IF IN >4 THEN T$ = "YA CAN'T! YER HANDS 'R FULL.": RETURN
1283 IF O$(J,3) = "1" THEN PRINT "YA ALREADY GOT IT!": RETURN
1286 IF VAL(O$(J,1)) = 0 AND I < >16 THEN 1290
1287 IN = IN +1: IF O$(J,2) = "-1" THEN IM = IM -1:O$(J,2) = "":O$(J,3) = "1": GOTO 1290
1288 O$(J,3) = "1":O$(J,2) = ""
1290 IF J < >9 AND J < >11 AND J < >2 THEN 120
1293 IF J = 9 THEN IF O$(8,2) = "-6" THEN O$(8,2) = "6
1295 IF J = 11 THEN IF O$(12,2) = "-8" THEN O$(12,2) = "8
1297 IF J = 2 THEN IF O$(18,2) = "-14" THEN O$(18,2) = "14"
1300 RETURN
1320 IF O$(J,3) < >"1" THEN T$ = "YA DON'T HAVE IT!": RETURN
1325 T$ = "OK":IN = IN -1:O$(J,2) = STR$(L):O$(J,3) = "": RETURN
1340 IF O$(5,3) < >"1" THEN 1890
1350 IF L = 7 THEN L = 8: GOTO 120
1360 IF L = 12 THEN L = 13
1370 GOTO 120
1390 GOSUB 120: ON J +1 GOTO 1400,1430,1440,1460,1470,1480,1490,1460,1460,1500,1510,1520,1530,1540,1460,1460,1460,1460,1460,1560,1570,1580,1590,1600,1610,1620,1460,1630,1460,1460,1460,1640,1460
1395 GOTO 1460
1400 IF VAL(O$(0,3)) <1 THEN T$ = "THEY'S LUMPY OLE LEATHER SADDLEBAGS.": RETURN
1410 PRINT "THEY HOLD ";: IF IM = 0 THEN PRINT "NOTHIN'.":T$ = "": RETURN
1415 FOR I = 6 TO 22: IF O$(I,2) = "-1" THEN PRINT " "O$(I,0)",";
1420 NEXT :T$ = CHR$(8) +".": RETURN
1430 T$ = "YA SEE A WEARY OLD GREY MULE.": RETURN
1440 T$ = "IT'S AN OLE TORN SACK.": IF O$(18,2) = "-14" THEN O$(18,2) = "14"
1450 RETURN
1460 T$ = "YA SEE NOTHIN' SPECIAL.": RETURN
1470 T$ = "IT'S AN OLD WINCHESTER SINGLE-SHOT.": RETURN
1480 T$ = "LOOKS LIKE A MAP TA TH' LOST DUTCHMAN'S MINE! THAR'S A SKETCH OF SOME BOULDERS.": RETURN
1490 T$ = "NOTHIN' SPECIAL," +C$ +"JUS' A LOADED SIX SHOOTER.": RETURN
1500 IF O$(8,2) = "-6" THEN T$ = "LOOKS LIKE SUMTHIN'S 'HIND THE BOTTLES.":O$(8,2) = "6": RETURN
1505 GOTO 1460
1510 T$ = "THAR'R 3 KEYS, TIED WITH A LEATHER STRAP": RETURN
1520 IF O$(12,2) = "-8" THEN T$ = "LOOKS LIKE THAR'S GLASS UNDER 'UM.":O$(12,2) = "8": RETURN
1525 GOTO 1460
1530 T$ = "IT'S AN OLE KEROSENE LAMP," +C$ +"FULL TA THE '" + STR$(LN) +" TURNS LEFT' MARK.": RETURN
1540 IF I = 11 THEN T$ = "IT SEZ'KEROSENE.'": RETURN
1550 T$ = "THAR'S WRITING ON IT.": RETURN
1560 IF O$(20,2) = "-17" THEN O$(20,2) = "17":T$ = "IT'S A MESSAGE!": RETURN
1565 GOTO 1460
1570 IF I = 11 THEN T$ = "IT SEZ :" +C$ +"BRING TREASURE TO SALOON, SAY 'SCORE'": RETURN
1575 GOTO 1550
1580 IF I = 11 THEN T$ = "IT SEZ:" +C$ +"WATCH FOR OTHER RIDER FANTASY CREATIONS ADVENTURES!": RETURN
1585 GOTO 1550
1590 T$ = "THEY'S A SAVAGE LOOKIN' BAND," +C$ +"'N THEY SEEN YA!": RETURN
1600 T$ = "JUST AN OLE ORE CART FULL O' ROCKS.": RETURN
1610 IF O$(5,2) = "-25" THEN O$(5,2) = "1":T$ = "THAR'S SOMTHIN' HERE!!": RETURN
1615 GOTO 1460
1620 IF I = 11 THEN T$ = "IT SAYS:" +C$ +"WELCOME TO FRONTERTOWN.": RETURN
1625 GOTO 1550
1630 IF O$(10,2) = "-6" THEN O$(10,2) = "6":T$ = "THAR'S A SET OF KEYS THAR!": RETURN
1635 GOTO 1460
1640 B = INT( RND(1) *3 +1): ON B GOTO 1650,1660,1670
1650 T$ = "IT'S A BARREL CACTUS.": RETURN
1660 T$ = "IT'S A CHOLLA CACTUS.": RETURN
1670 T$ = "IT'S A SAGUARO CACTUS.": RETURN
1690 IF J = 4 AND I = 38 THEN 1780
1700 IF J < >1 OR VAL(O$(1,3)) <0 THEN T$ = "SORRY, B' THAT AIN'T POSSIBLE.": RETURN
1710 IF I < >38 THEN 1720
1715 IF O$(1,2) = "" THEN T$ = "TENDERFOOT! YA HAVE TA LEAD HIM FIRST.": RETURN
1717 GOTO 1780
1720 IF O$(1,3) = "1" THEN 1320
1723 IF O$(7,3) = "1" THEN IF I < >16 THEN T$ = "TRY 'LEAD.'": RETURN
1730 ON I -13 GOTO 1740,1750,1760,1770
1740 T$ = "HE GOT AWAY FROM YA.": RETURN
1750 T$ = "YER TOO SLOW, HE GOT AWAY.": RETURN
1760 IF O$(7,3) < >"1" THEN T$ = "BAD LUCK, YA TRIPPED AND HE RUN OFF.":O$(1,3) = "":O$(1,2) = STR$(L): RETURN
1763 IF O$(1,3) = "" THEN 1280
1766 GOTO 1320
1770 T$ = "HE BUCKED YA OFF.": RETURN
1780 INPUT "WITH WHAT?";QM$: IF J = 4 THEN 1800
1782 IF LEFT$(QM$ +" ",3) < >"SAD" THEN T$ = "IT FELL OFF." +C$ +"HE GOT AWAY.":O$(1,3) = "":IN = IN -1:O$(1,2) = STR$(L): RETURN
1790 IF O$(0,3) = "1" THEN O$(0,3) = "2":IN = IN -1: GOTO 1060
1795 GOTO 1320
1800 IF LEFT$(QM$ +" ",3) < >"BUL" THEN 1050
1805 IF O$(8,3) < >"1" OR O$(4,3) < >"1" THEN 1320
1810 GOTO 120
1820 IF O$(J,3) < >"1" THEN 1320
1822 INPUT "ON OR IN WHAT? (IE 'ON TABLE') ?";QM$:P$ = LEFT$(QM$ +" ",2): IF P$ < >"IN" AND P$ < >"ON" THEN T$ = "HUH?": RETURN
1830 M1$ = MID$ (QM$,4,3)
1840 IF P$ < >"ON" THEN 1850
1841 IF M1$ = "MUL" THEN 1790
1843 IF J < >13 THEN 1320
1845 IF LM = 0 THEN T$ = "IT'S EMPTY.": RETURN
1847 LM = 0: GOTO 1320
1850 IF M1$ < >"SAD" THEN 1860
1852 IF J <5 OR J = 19 OR J = 22 THEN T$ = "SORRY, IT DON'T FIT.": RETURN
1855 IF IM >4 THEN T$ = "THE BAGS 'R FULL.": RETURN
1857 O$(J,2) = "-1":O$(J,3) = "":IN = IN -1:IM = IM +1:T$ = "OK": RETURN
1860 IF M1$ = "MUL" THEN T$ = "YA GOT KICKED!": RETURN
1870 IF M1$ < >"LAN" THEN 1050
1880 T$ = "JAR'S EMPTY.": RETURN
1890 T$ = "YA CAN'T DO THAT... YET!
1900 PRINT T$:T$ = "": GOTO 100
1920 PRINT "YA GOT WITH YA: ";: IF IN = 0 AND O$(1,3) < >"1" THEN T$ = "NOTHIN'": RETURN
1930 B = VAL(O$(0,3)):X1 = B: IF B < >1 THEN 1940
1933 PRINT : PRINT O$(0,0)", CONTAINING: ";: FOR I = 1 TO 22: IF O$(I,2) = "-1" THEN PRINT O$(I,0)". ";:X1 = 2
1936 NEXT : IF X1 < >2 THEN PRINT "NOTHIN'! ";
1940 IF O$(1,3) = "1" THEN PRINT : PRINT "THE MULE, WHICH YER LEADIN. ";: IF B = 2 THEN PRINT "(CARRYIN' SADDLEBAGS) ";
1950 PRINT :X1 = 0: FOR I = 2 TO 22: IF VAL(O$(I,3)) <1 THEN 1970
1955 IF CL = 1 AND I = 12 THEN PRINT "LIT ";
1960 PRINT O$(I,0)". ";
1970 NEXT
1980 T$ = "": RETURN
2000 IF L = 19 THEN HOME : PRINT " YA FELL 100 FEET 'N LANDED ON ROCKS.": PRINT " YER DEAD.": GOTO 2220
2005 IF J = 23 OR J = 32 OR M1$ = "P" THEN T$ = "OK": RETURN
2006 GOTO 1050
2010 T$ = "WHERE?": RETURN
2020 IF L = 25 THEN L = 26: GOTO 120
2030 IF L = 26 THEN L = 25: GOTO 120
2040 GOTO 120
2100 DATA ,,,,,,,,IN A MINER'S SHACK,WINDOW. DOOR,,1,3,3,,,IN A DESERT,ROAD. MOUNTAINS. DESERT,WNES,2,4,2,2,2,ON A DIRT PATH,MINER'S SHACK. ROAD. MOUNTAINS," W ",5,1,4,2,2
2110 DATA ON A DIRT ROAD,MOUNTAINS. PATH. DESERT. TOWN,NE S,2,7,3,2,5,IN A GHOST TOWN,SALOON," N ",1,6,4,,,IN A SALOON,,W ,1,5,,,
2120 DATA AT THE SUPERSTITION MOUNTAINS,ROAD. DESERT,S N ,4,4,2,2,2,AT WEAVER'S NEEDLE,,NS ,1,9,7,,
2130 DATA IN A NARROW DEFILE,BUSHES. CAVES," NS",1,11,10,12,8,IN A SMALL CAVE,,E ,1,9,,,,BEHIND A BUSH,BUSH.,W ,1,9,,,,IN A BOX CANYON,BUSHES. TREES. BOULDERS," S",4,12,12,12,9
2140 DATA IN FRONT OF A HIDDEN MINE,MINE SHAFT,ESNW,8,14,12,12,12,IN THE MOUTH OF A DIM MINE,MINE SHAFT,EW ,1,15,13,,,IN A MINE,DARK TUNNEL,EW ,6,16,14,,
2150 DATA AT THE END AF A TUNNEL,IRON DOOR," W ",1,17,15,,,IN A LARGE CHAMBER,IRON DOOR,WNES,1,16,19,18,20,IN A MAZE OF TUNNELS,,NSEW,6,18,18,18,18,IN FRONT OF A PIT,DARK HOLE," S ",7,23,17,,
2160 DATA AT AN INTERSECTION,," SNW",6,,22,17,21,IN A DEAD END TUNNEL,,E ,8,20,,,,IN A BLOCKED TUNNEL,,N ,8,20,,,,AT THE BOTTOM OF A SHAFT,WALL,S ,8,24,,,
2170 DATA IN A TUNNEL,,NS ,6,23,25,,,AT THE END OF A TUNNEL,LADDER," N ",6,26,24,,,AT THE TOP OF A LADDER,,,6,1,25,,
2180 DATA SADDLEBAGS,2,1,MULE,,3,BURLAP SACK,4,14,SHOVEL,4,1,RIFLE,4,1,MAP,1,-25,GUN,1,-1,CARROTS,1,-1,BOX OF RIFLE BULLETS,1,-6,WHISKEY BOTTLES,2,6,KEYS,1,-6,PILE OF BONES (MINE),2,8
2190 DATA LANTERN,2,-8,JAR OF LIQUID,1,-11,*SPANISH COINS*,1,-10,*TOURQUISE*,1,-23,#SILVER#,1,-21,#GOLD#,1,-22,MATCHES,1,-14,CRATES,3,17,NOTE,1,-17,PAPER,1,6,INDIANS,,11
2200 DATA ORE CART,,14,BED,,1,SIGN,,5,BROKEN GLASS,,6,TABLES,,6,CHAIRS,,6,ROCKS,,10,WOODEN RAILS,,15,CACTUS,,2,TRAP DOOR,,26
2210 DATA GO ,ENT,RUN,QUI,DIG,CLI,INV,JUM,DRO,GET,EXA,REA,LOO,MOV,CAT,CHA,LEA,RID,PUT,PLA,PIC,PUS,PUL,SHO,OPE,CLO,GIV,BUR,LIG,DRI,BRE,HIT,UNL,LOC,TAK,LIS,SAY,FEE,LOA,UNT,FOL,POU,EAT,NOR,SOU,EAS,WES
2220 VTAB 24: INPUT "DO YA WANT TA TRY AGIN?";QM$: IF LEFT$(QM$ +" ",1) = "Y" THEN RUN
2230 POKE 34,0: POKE 35,24: HOME : NEW
2300 PRINT "TRY ESAM'NIN THIN'S.": RETURN
2310 PRINT "ROADS GO PLACES.": RETURN
2320 PRINT "MAYBE THE TRAIL GOES SUMWHAR.": RETURN
2330 IF O$(5,3) < >"1" THEN PRINT "YA GOT A MAP?": RETURN
2340 PRINT "TRY 'FOLLOW.'": RETURN
2350 IF VAL(O$(1,2)) = L THEN PRINT "THE MULE LOOKS THIN.": RETURN
2360 GOTO 2300
2370 PRINT "KEEP GOIN'.": RETURN
2380 PRINT "IT'S SLIPRY, BUTCHA MIGHT MAKE IT DOWN.": RETURN
2390 PRINT "THIS HERE'S A MINE, YA KNOW.": RETURN
2500 IF J = 7 THEN T$ = "THEY TASTE PURTY GOOD.": RETURN
2510 T$ = "CAN'T DO THAT... WEIRDO !": RETURN
2520 INPUT "SURE?";QM$: IF LEFT$(QM$ +" ",1) < >"Y" THEN 390
2530 INPUT "NAME?";QM$:QM$ = "LDG/" +QM$: ONERR GOTO 4100
2535 PRINT "OPEN "QM$: PRINT "WRITE "QM$
2540 PRINT L","CL","LN","IN","LM","U","U1","IM
2541 FOR X = 0 TO 32: PRINT O$(X,1)","O$(X,2)","O$(X,3): NEXT
2550 PRINT "CLOSE "QM$: POKE 216,0: PRINT "SAVED!": GOTO 390
4000 POKE 216,0: PRINT PRINT "CLOSE "QM$:EE = PEEK(222): IF EE = 2 OR EE = 3 OR EE = 11 THEN PRINT "BAD NAME. TRY ANOTHER.": GOTO 80
4010 IF EE = 6 THEN PRINT "NO FILE NAMED "QM$: GOTO 70
4020 PRINT ">>> DISK PROBLEM. ERROR #"EE: GOTO 70
4100 POKE 216,0: PRINT "CLOSE"QM$:EE = PEEK(222)
4110 IF EE = 2 OR EE = 3 OR EE = 11 THEN PRINT "BAD NAME. TRY ANOTHER.": GOTO 2530
4120 IF EE = 4 THEN PRINT "DISK WRITE PROTECTED!": GOTO 2520
4130 IF EE = 9 THEN PRINT "DISK FULL!": PRINT "DELET"QM$: GOTO 2520
4140 IF EE = 10 THEN PRINT "FILE LOCKED! (AND I DIDN'T DO IT!)": GOTO 390
4150 PRINT ">>> DISK PROBLEM. ERROR #"EE: GOTO 390
9999 END
10000 REM ***************
10001 REM CONTRUBUTED BY
10002 REM JERRY FICKE

Text found in Apple_II_Compilation_007_19xx__.do/SORCERY.bas:

0 REM CHRISTELLA ENTERPRISE
2 REM AN INANE ADVENTURE
10 HOME : VTAB 10: HTAB 12
11 FLASH : PRINT "SWORDS AND SORCERY": NORMAL : FOR D = 1 TO 2000: NEXT
12 W2 = 1: HOME : INPUT "PLEASE ENTER YOUR NAME ";N$:I3 = ASC(N$)
20 PRINT : PRINT "GOOD LUCK, ";N$;", YOU NEED IT!"
21 PRINT : PRINT
23 GOSUB 5000
30 IF RND(I1) >.7 THEN 200
40 PRINT "A DRYAD WISHES TO GUIDE YOU."
50 PRINT "WILL YOU LET HER?
60 GOSUB 3000
70 ON I1 GOTO 80,120
80 F1 = 0
90 IF RND(I1) >.2 THEN GOSUB 3100
100 GOTO 200
120 F1 = 1
200 W1 = F1
210 PRINT : PRINT "THERE ARE THREE PATHS INTO THE FOREST.": PRINT "ONE IS CORRECT."
220 C1 = INT(3 * RND(I1) +.9999)
222 Y1 = INT(3 * RND(2) +.9999)
225 IF RND(I1) >.4 THEN YI = C1
230 PRINT : PRINT "DO YOU WISH TO CONSULT AN ORACLE?": GOSUB 3000
250 ON I1 GOTO 400,260
260 PRINT : PRINT "HOW MANY MAIDENS SHOULD BE SACRIFICED?"
280 INPUT V1
285 V1 = INT(V1)
290 IF V1 >2 * RND(I1) THEN 320
295 PRINT : PRINT "THE ORACLE IS OFFENDED!"
300 C2 = C2 -1
320 IF V1 *F1 <10 * RND(I1) THEN 350
330 GOSUB 3100
350 IF C2 <0 THEN 388
360 IF RND(I1) <.4 -(V1/10) THEN 388
370 PRINT "THE ORACLE SAYS PATH ";Y1
380 P1 = 1
381 GOTO 400
388 PRINT : PRINT "THE SIGNS ARE UNCLEAR."
400 PRINT "CHOOSE PATH 1,2 OR 3."
410 INPUT X1
415 X1 = INT(X1)
420 IF X1 <1 OR X1 >3 THEN 400
426 L1 = 100 *( RND(X1) +1)
427 IF X1 = C1 THEN 444
431 C2 = C2 -2:L1 = L1 +50
444 C2 = C2 +1
445 T1 = 0
450 C2 = C2 +.5 * RND(X1) +F1 +P1 +.2 *V1 * SGN(5.1 -V1)
490 C3 = 0
520 PRINT : PRINT "YOU HAVE COME TO A FORK IN THE PATH."
525 C1 = INT(2 * RND(I1) +.9999)
530 Z1 = W1 -F1:S1 = 8 -Z1 -G1/(1 +Z1)
535 IF S1 <4 THEN S1 = 4
540 IF 3.5 * RND(X1) >C2 THEN L1 = L1 +1
545 L2 = 7 +20 * RND(X1)
550 L0 = L2
560 IF F1 = 0 THEN 660
570 PRINT "DO YOU WANT TO ASK THE NYMPH WHICH ONE?"
580 GOSUB 3000
590 ON I1 GOTO 660,600
600 IF RND(I1) >.5 +C2/50 THEN 650
610 PRINT "SHE SAYS ";C1
620 GOTO 740
650 PRINT "SHE DOESN'T KNOW."
655 GOTO 740
660 PRINT "WILL YOU CAST LOTS TO DECIDE?"
661 PRINT
670 GOSUB 3000
674 ON I1 GOTO 740,680
680 PRINT "THE LOT SAYS ";
685 IF RND(I1) >.5 +C2/10 THEN 700
690 X1 = C1
695 GOTO 730
700 IF C1 = 2 THEN X1 = 1
710 IF C1 = 1 THEN X1 = 2
730 PRINT X1
740 PRINT : PRINT "DO YOU CHOOSE 1 OR 2?";: INPUT " ";X1
755 X1 = INT(X1 +.0001)
760 IF X1 >2 THEN 740
770 IF X1 <1 THEN 740
780 D0 = 0
790 IF X1 < >C1 THEN 820
800 C2 = C2 + RND(XI) + SGN(.5 - RND(I1))
810 C3 = 0
815 GOTO 840
820 C2 = C2 -.2
830 C3 = -1
840 IF T1 = 0 THEN 890
890 L2 = L2 -S1
895 I2 = I2 +1
900 IF E1 < >0 THEN 940
910 IF RND(X1) >.15 +.2 *F1 THEN 940
920 PRINT : PRINT "YOU FIND AN ENCHANTED SWORD!"
925 C2 = C2 +.2:E1 = 1
940 IF RND(I1) -.5 *(F1 +C3) <.95 THEN 960
950 PRINT : PRINT "SNAKE!!!"
955 GOSUB 3490
960 T1 = T1 +1
970 IF RND(X1) >.8 +(C2 +C3)/30 THEN GOSUB 4500
1200 IF RND(X1) >.95 THEN GOSUB 7000
1300 IF RND(I1) <.03 THEN GOSUB 6100
1310 P3 = 0
1350 IF RND(X1) >.99 +(C2 -I2/10)/100 THEN GOSUB 6300
1445 IF W1 = 0 THEN 1460
1450 IF RND(0) >.95 +(C2 +C3)/50 THEN GOSUB 5100
1460 IF RND(0) <.95 THEN 1500
1470 PRINT : PRINT "GOLD!!!!!"
1475 PRINT "HOW MANY SACKS WILL YOU TAKE?";: INPUT " ";X1
1490 G1 = G1 + INT(X1)
1500 IF T1 >10 -2 +F1 THEN GOSUB 3500
1510 IF RND(0) >.05 THEN 1540
1520 PRINT : PRINT "YOU MEET AN ESCAPED SLAVE GIRL "
1530 W1 = W1 +1
1540 IF L2 >0 THEN 840
1550 L1 = L1 -L0 *.85
1560 IF L1 <20 THEN GOSUB 4000
1570 IF C3 < > -1 THEN 520
1580 IF RND(I1) <.9 THEN 520
1590 IF RND(X1) >.5 THEN GOSUB 6100
1595 PRINT : PRINT "DEAD END!!!"
1600 L2 = L2 +L0
1615 L1 = L1 +L0
1616 C3 = 0
1700 GOTO 840
2980 GOTO 840
2990 SPEED= 255: PRINT : PRINT "THIS 'GAME' IS OVER!": PRINT "DO YOU WISH TO TRY AGAIN?"
2991 GOSUB 3000
2992 IF I1 = 1 THEN 2995
2993 IF I1 = 2 THEN RUN
2995 PRINT : PRINT "TOO BAD. HOPE TO SEE YOU IN THE FOREST"
2996 PRINT "AGAIN.": PRINT CHR$(13) + CHR$(4);"RUN HELLO"
3000 V = PEEK(37) +1
3002 VTAB V:I1 = 0: CALL -958: INPUT I1$
3003 IF LEFT$(I1$,1) = "Y" OR I1$ = "AFFIRMATIVE" THEN I1 = 2
3010 IF LEFT$(I1$,1) = "N" THEN I1 = 1
3015 IF I1 = 0 THEN 3002
3025 RETURN
3100 PRINT "THE NYMPH IS VERY OFFENDED."
3105 PRINT "SHE CURSES YOU AND GOES!"
3110 F1 = 0:W1 = 0:C2 = C2 -1
3120 RETURN
3490 PRINT "YOU ARE HURT."
3500 PRINT "YOU MUST REST."
3502 PRINT "YOU'VE GONE ";I2 *S1;" KM."
3510 T1 = 0
3515 GOSUB 5000
3520 D3 = D3 +1 +W1 -F1
3530 IF D3 <4 -W1 +F1 THEN 3700
3540 IF D4 < >0 THEN 3650
3550 PRINT : PRINT "YOU ARE OUT OF FOOD!"
3560 D4 = 1:C2 = C2 - RND(0)
3570 GOTO 3700
3650 F5 = F5 +1
3660 C2 = C2 - RND(I1) +.2 *F1
3700 IF RND(X1) >1 -(I2 +F8)/100 THEN 3715
3702 PRINT : PRINT "TIME TO MOVE ON.": FOR I = 1 TO 1000: NEXT I: HOME
3705 IF F5 <7 THEN RETURN
3710 PRINT : PRINT "YOU STARVE TO DEATH!": GOTO 2990
3715 PRINT "YOU ARE CAPTURED BY GOBLINS!"
3720 IF E1 < >1 THEN 3800
3725 PRINT "THEY WANT YOUR SWORD."
3730 PRINT "WILL YOU TRADE IT FOR FREEDOM?"
3735 GOSUB 3000
3740 ON I1 GOTO 3800,3750
3750 PRINT "AGREED.":E1 = -.8
3752 IF P3 = 1 THEN PRINT "THEY THROW YOU BACK IN THE PIT."
3755 GOTO 3705
3800 D9 = INT(3 * RND(I1) +.9999)
3805 IF G1 0 THEN 3880
3860 PRINT : PRINT "YOU ARE ENSLAVED!"
3870 GOTO 2990
3880 PRINT "YOU ARE SOLD TO THE SATYRS."
3890 GOSUB 5130
3891 GOTO 3752
4000 IF R1 < >0 THEN 4200
4020 PRINT "YOU ARE AT THE ENTRANCE TO THE DUNGEON."
4022 PRINT "THERE IS A GUARD!"
4025 GOSUB 7990
4110 R1 = 1:W1 = W1 +1
4120 PRINT : PRINT "YOU HAVE RELEASED THE PRINCESS.": PRINT
4124 GOSUB 3500
4200 IF L1 >0 THEN RETURN
4205 IF R1 < >1 THEN 4275
4207 PRINT "YOU MADE IT!!!!"
4210 PRINT "YOU ARE A HERO."
4215 IF G1 <2 THEN 4240
4220 PRINT : PRINT "YOU MARRY THE PRINCESS."
4225 FOR I = 1 TO 500: NEXT I: GOTO 2990
4240 PRINT : PRINT "TOO BAD YOU ARE TOO POOR"
4245 PRINT "TO MARRY THE PRINCESS."
4247 PRINT : PRINT "YOU LIVE THE REST OF YOUR LIFE"
4250 PRINT "IN QUIET POVERTY."
4255 GOTO 2990
4275 IF R1 < > -2 THEN 4305
4280 PRINT : PRINT "YOU LET THE PRINCESS BETAKEN ALIVE BY SATYRS."
4290 PRINT "YOU ARE JUSTIFIABLY TORTURED TO DEATH!"
4300 GOTO 2990
4305 PRINT : PRINT "YOU HAVE FAILED!!!"
4310 GOTO 4247
4500 PRINT : PRINT "TROLL!!!"
4510 PRINT "WILL YOU FIGHT?"
4520 GOSUB 3000
4530 ON I1 GOTO 4540,4560
4540 GOSUB 4700
4550 RETURN
4560 IF E1 = 0 THEN 4580
4570 IF RND(I1) >.2 THEN 4580
4574 PRINT : PRINT "THE TROLL RUNS!"
4576 RETURN
4580 IF RND(I1) +.3 *E1 >.5 THEN 4610
4585 IF RND(X1) >.3 THEN 4590
4586 GOSUB 3490
4587 RETURN
4590 PRINT "YOU ARE KILLED!!!"
4600 PRINT : GOTO 2990
4610 PRINT "THE TROLL IS DEAD!"
4620 IF RND(I1) +.05 *E1 <.4 THEN GOSUB 3490
4630 RETURN
4700 PRINT : PRINT "RUN!!"
4710 L1 = L1 +4 *S1 *( RND(X1) -.7)
4720 T1 = T1 +1
4725 IF RND(I1) >.7 THEN GOSUB 6100
4730 RETURN
5000 FOR I1 = 1 TO 200
5001 X1 = RND(I3)
5003 NEXT I1: RETURN
5100 PRINT "OH NO! SATYRS."
5105 IF E1 < >1 THEN 5130
5120 PRINT "THEY RUN FOR YOUR SWORD."
5121 PRINT "YOU FIGHT THEM OFF WITH YOUR ENCHANTED SWORD."
5125 RETURN
5130 PRINT "THEY WILL GO IF YOU FIGHT"
5135 PRINT "THEIR CHAMPION.": PRINT "WILL YOU FIGHT?"
5140 GOSUB 3000
5145 ON I1 GOTO 5200,5160
5160 GOSUB 7990
5165 IF RND(X1) <.2 THEN 5200
5170 RETURN
5200 PRINT : PRINT "THE SATYRS WANT THE FEMALES."
5205 W1 = 0:F1 = 0: IF R1 = 1 THEN R1 = -2
5210 PRINT "WILL YOU ALLOW THIS?"
5220 GOSUB 3000
5230 ON I1 GOTO 5240,5260
5240 PRINT "THEY KILL YOU AND TAKE THE WOMEN!"
5250 GOTO 2990
5260 PRINT "THE WOMEN ARE TAKEN."
5270 IF RND(I1) <.03 THEN 5310
5280 PRINT "THEY CURSE YOU."
5290 C2 = -5
5310 IF RND(X1) >.3 THEN RETURN
5320 PRINT "THE SATYRS KILL YOU ANYWAY."
5340 GOTO 2990
6100 PRINT "YOU HAVE FALLEN INTO A PIT!!"
6105 P3 = 1
6110 IF RND(I1) >.5 THEN GOSUB 3490
6120 PRINT "YOU MUST ESCAPE. WILL YOU TRY TO CLIMB"
6121 PRINT "OUT (1), OR YELL FOR HELP (2)?"
6150 INPUT X1:X1 = INT(X1)
6152 IF X1 <1 OR X1 >2 THEN 6120
6154 P7 = 0
6155 ON X1 GOTO 6160,6200
6160 IF RND(I1) <.5 -P7/10 THEN 6180
6162 PRINT "YOU FALL WHILE TRYING TO CLIMB."
6165 IF RND(X1) <.2 THEN GOSUB 3490
6167 P7 = P7 +1: IF P7 <5 THEN 6160
6170 PRINT "TOO DEEP. YELL FOR HELP."
6172 GOTO 6200
6180 PRINT "YOU'RE OUT!": RETURN
6200 SPEED= 75: FOR I = 1 TO 5
6201 PRINT "HELP! ";
6202 NEXT I: SPEED= 0: PRINT "HELP? ": SPEED= 100
6203 GOSUB 5000
6204 IF RND(I1) <.3 THEN 6200
6205 PRINT "A ROPE HAS BEEN LOWERED."
6207 P3 = 0
6210 Y1 = INT(3 * RND(I1) +.9999)
6215 ON Y1 GOTO 6220,6225,6230
6220 GOSUB 4500: RETURN
6225 GOSUB 3715: RETURN
6230 PRINT : PRINT "YOU ARE RESCUED BY A WOMAN!"
6231 W1 = W1 +1
6232 RETURN
6300 PRINT "IT IS A NECROMANCER...."
6305 IF RND(X1) >.6 THEN 6392
6310 IF F1 < >1 THEN 6326
6320 PRINT : PRINT "THE NYMPH GOES MAD."
6325 W1 = W1 -1:F1 = 0
6326 IF E1 = 1 THEN 6375
6330 IF W1 = 0 THEN 6350
6335 W1 = 0
6340 PRINT "THE WOMEN ARE SENT TO HIS"
6345 PRINT "UNDEAD AS PLAYTHINGS."
6350 PRINT "YOU ARE TRANSFORMED INTO"
6351 PRINT "A GELDED WATER BUFFALO"
6352 PRINT "AND DRIVEN INTO A PIT."
6360 PRINT : PRINT "BOY DID YOU LOOSE!!!!"
6370 GOTO 2990
6375 PRINT "HE TAKES YOUR SWORD!":E1 = -1.5
6380 PRINT "YOU ARE CAST INTO A PIT."
6385 GOSUB 6110
6390 RETURN
6392 GOSUB 4700
6395 RETURN
7000 PRINT : PRINT "UGH! RATS, MILLIONS OF THEM."
7010 GOSUB 4700
7020 RETURN
7990 W3 = 2:H1 = 1:H2 = 1
7992 W2 = 1 +3 * RND(I1)
7995 H3 = 2 + SGN(E1)
8000 PRINT : PRINT "IT'S A LARGE TROLL."
8040 PRINT "THE BATTLE BEGINS..."
8050 PRINT : PRINT "YOU CIRCLE FOR POSITION."
8051 PRINT : FOR I1 = 1 TO 20
8052 X1 = RND(I1)
8053 NEXT I1
8055 W3 = W3 -.05:H1 = H1 -.05
8057 H2 = H2 -.05
8060 PRINT "HE ATTACKS!"
8070 X1 = 1 + INT(2.9999 * RND(I1))
8080 ON X1 GOTO 8090,8100,8110
8090 PRINT "HE TAKES A WILD CUT."
8091 GOTO 8120
8100 PRINT "HE THRUSTS AT YOUR BODY."
8105 GOTO 8120
8110 PRINT "HE TRIES A HEAD CUT!"
8120 IF RND(I1) >.5 +.3 *H2/W2 THEN 8340
8130 X1 = 1 + INT(2.5 * RND(I1))
8140 ON X1 GOTO 8150,8160,8170
8150 PRINT : PRINT "YOU STOP HIS BLOW ON YOUR SWORD"
8151 PRINT "AND BACK AWAY."
8155 GOTO 8050
8160 PRINT : PRINT "YOU DUCK UNDER HIS SWORD"
8161 PRINT "TO ATTACK!"
8165 GOTO 8175
8170 PRINT : PRINT "YOU PARRY THEN ATTACK."
8175 FOR I1 = 1 TO H3
8180 IF RND(I1) >.1 THEN 8190
8185 PRINT : PRINT "YOU MISSED HIM!": GOTO 8250
8190 X1 = 1 + INT(2.999 * RND(I1))
8195 ON X1 GOTO 8200,8220,8230
8200 PRINT "YOU GOT HIS LEG."
8205 W2 = W2 -H2/5:W3 = W3 -H2/5
8210 GOTO 8250
8220 PRINT "YOU'VE SLASHED HIS ARM."
8225 W2 = W2 -H2/3:W3 = W3 -H2/5
8227 GOTO 8250
8230 PRINT "YOU SCORE TO HIS BODY."
8245 W2 = W2 -.1:W3 = W3 -.25
8250 NEXT I1
8251 IF W2 <.1 THEN W2 = .1
8255 IF W3 >.05 THEN 8050
8260 PRINT "HE'S DOWN!!!"
8265 PRINT "YOU HAVE FINISHED HIM OFF!!"
8290 RETURN
8340 PRINT "YOU'RE HIT!"
8355 H1 = H1 -.2:H2 = H2 -.2
8357 IF H1 <.05 THEN 8370
8360 PRINT "YOU STAGGER AWAY.": GOTO 8050
8370 PRINT "YOU'RE DOWN!!!"
8380 PRINT "HE CLOSES FOR THE KILL!"
8390 IF RND(I1) >.1 +E1/20 THEN 8400
8392 PRINT "YOU MAKE A LUCKY THRUST!!"
8395 PRINT "HE'S ";: SPEED= 0: PRINT "DEAD!!!": SPEED= 100
8396 RETURN
8400 PRINT "YOU ARE KILLED!!!!"
8405 GOTO 2990
8410 REM
63800 REM =========================
63801 REM = CHRISTELLA ENTERPRISE =
63802 REM = 22513 NORCREST DRIVE =
63803 REM = SCS,MICHIGAN 48080 =
63804 REM =========================